From 8a2469d72578f05aa2543d27f67d6c034a68aa8f Mon Sep 17 00:00:00 2001
From: Oliver Kiddle <opk@users.sourceforge.net>
Date: Fri, 1 Feb 2002 14:56:20 +0000
Subject: 16449: new chkconfig completion for both the RedHat and IRIX commands

---
 Completion/Unix/Command/_chkconfig | 33 +++++++++++++++++++++++++++++++++
 1 file changed, 33 insertions(+)
 create mode 100644 Completion/Unix/Command/_chkconfig

(limited to 'Completion/Unix/Command/_chkconfig')

diff --git a/Completion/Unix/Command/_chkconfig b/Completion/Unix/Command/_chkconfig
new file mode 100644
index 000000000..92bc60c60
--- /dev/null
+++ b/Completion/Unix/Command/_chkconfig
@@ -0,0 +1,33 @@
+#compdef chkconfig
+
+local curcontext="$curcontext" state line ret=1
+
+case $OSTYPE in
+linux*)
+  _arguments -C \
+    '(- 2)--list[list services]' \
+    '(-)--level[specify runlevels to apply to]:-:_values -s "" "run levels" 1 2 3 4 5 6 7' \
+    '(- 2)--add[add new service]' \
+    '(- 2)--del[remove service from chkconfig management]' \
+    '1:service name:->services' \
+    '2:state:(on off reset)' && ret=0
+
+  if [[ -n "$state" ]]; then
+    _wanted services expl 'system service' \
+	compadd ${${${(f)"$($words[1] --list)"}%%[ :]*}##$'\t'*} && ret=0
+  fi
+;;
+irix*)
+  _arguments -C \
+    '(- 1)-s[print state of configuration flags]' \
+    '(1 -s)-f[set flag state]:configuration flag:->flag:state:(on off)' \
+    '1:configuration flag:->flag' && ret=0
+
+  if [[ -n "$state" ]]; then
+    _wanted conf-flags expl 'configuration flag' \
+	compadd ${${${(f)"$($words[1])"}[4,-1]##$'\t'}%% *} && ret=0
+  fi
+;;
+esac
+
+return ret
-- 
cgit 1.4.1