From 1094863b35d48a93de5cc20bc65121a2712db2d2 Mon Sep 17 00:00:00 2001
From: Clint Adams <clint@users.sourceforge.net>
Date: Mon, 12 Apr 2010 13:23:33 +0000
Subject: 27876: completion for axi-cache (from apt-xapian-index).

---
 Completion/Debian/Command/_axi-cache | 29 +++++++++++++++++++++++++++++
 1 file changed, 29 insertions(+)
 create mode 100644 Completion/Debian/Command/_axi-cache

(limited to 'Completion/Debian')

diff --git a/Completion/Debian/Command/_axi-cache b/Completion/Debian/Command/_axi-cache
new file mode 100644
index 000000000..0c137c700
--- /dev/null
+++ b/Completion/Debian/Command/_axi-cache
@@ -0,0 +1,29 @@
+#compdef axi-cache
+
+local expl
+
+_arguments \
+  '--version[version]' \
+  '(-h --help)'{-h,--help}'[help]' \
+  '(-s --sort)'{-s,--sort=}':sort value:('${(j: :)${${(M)${(f)"$(</var/lib/apt-xapian-index/values)"}:#[a-z]*}%%	*}}')' \
+  '--tags[show tags, not packages]' \
+  '*:args:->args' && return 0
+
+if (( CURRENT == 2 )); then
+  _wanted tag expl 'axi-cache commands' \
+    compadd help search more last show again
+else
+  case "$words[2]" in
+    (search|show|again)
+      _wanted tag expl 'terms/query' \
+        compadd -- $($service $words[2] --tabcomplete=plain -- $words[CURRENT])
+    ;;
+    (more|last)
+      _wanted tag expl 'count' \
+        compadd -- 1 2 3 4 5 6 7 8 9 0
+    ;;
+    (*)
+      _files
+    ;;
+    esac
+fi
-- 
cgit 1.4.1