From e6a78cc112e727eec71ce8dc9a16f40189ef8ca0 Mon Sep 17 00:00:00 2001
From: Paul Ackersviller <packersv@users.sourceforge.net>
Date: Mon, 5 Nov 2007 01:59:42 +0000
Subject: Merge of 22953: didn't work if file started with a hyphen.

---
 Completion/Base/Widget/_most_recent_file | 24 ++++++++++++++++++++++++
 1 file changed, 24 insertions(+)
 create mode 100644 Completion/Base/Widget/_most_recent_file

(limited to 'Completion/Base')

diff --git a/Completion/Base/Widget/_most_recent_file b/Completion/Base/Widget/_most_recent_file
new file mode 100644
index 000000000..68d1c91a2
--- /dev/null
+++ b/Completion/Base/Widget/_most_recent_file
@@ -0,0 +1,24 @@
+#compdef -k complete-word \C-xm
+
+# Complete the most recently modified file matching the pattern on the line
+# so far: globbing is active, i.e. *.txt will be expanded to the most recent
+# file ending in .txt
+#
+# With a prefix argument, select the Nth most recent matching file;
+# negative arguments work in the opposite direction, so for example
+# `Esc - \C-x m' gets you the oldest file.
+
+local file tilde etilde
+if [[ $PREFIX = \~*/* ]]; then
+  tilde=${PREFIX%%/*}
+  etilde=${~tilde}
+  # PREFIX and SUFFIX have full command line quoting in, but we want
+  # any globbing characters which are quoted to stay quoted.
+  eval "file=($PREFIX*$SUFFIX(om[${NUMERIC:-1}]N))"
+  file=(${file/#$etilde})
+  file=($tilde${(q)^file})
+else
+  eval "file=($PREFIX*$SUFFIX(om[${NUMERIC:-1}]N))"
+  file=(${(q)file})
+fi
+(( $#file )) && compadd -U -i "$IPREFIX" -I "$ISUFFIX" -f -Q -- $file
-- 
cgit 1.4.1