From da55261a17ca9b5b35191db1c1c0cdccd09cb702 Mon Sep 17 00:00:00 2001
From: Tanaka Akira <akr@users.sourceforge.net>
Date: Thu, 9 Mar 2000 11:46:27 +0000
Subject: zsh-workers/10013

---
 Completion/Builtins/_compdef | 55 ++++++++++++++++++++++++++++----------------
 Completion/Builtins/_zpty    | 23 ++++++++++++++++++
 Completion/User/_getconf     | 37 +++++++++++++++++++++++++++++
 3 files changed, 95 insertions(+), 20 deletions(-)
 create mode 100644 Completion/Builtins/_zpty
 create mode 100644 Completion/User/_getconf

diff --git a/Completion/Builtins/_compdef b/Completion/Builtins/_compdef
index 7b4b0cb35..772c6b90d 100644
--- a/Completion/Builtins/_compdef
+++ b/Completion/Builtins/_compdef
@@ -1,24 +1,39 @@
 #compdef compdef
 
-local expl func base=2
+local state line expl list disp
 
-while [[ $words[base] = -* ]]; do
-  case $words[base] in
-    -d) delete=yes ;;
-    -p) type=pattern ;;
-    -k) type=key ;;
-  esac  
-  (( base++ ))
-done
+_arguments -C -s \
+  '(-d)-a[make function autoloadable]' \
+  '(-d -p -P)-n[leave existing definitions intact]' \
+  '(-a -n -p -P -k -K)-d[delete]:*:completed command:->ccom' \
+  '(-n -d -P -k -K)-p[completion for command matching pattern]:completion function:->cfun:pattern' \
+  '(-n -d -p -k -K)-P[as -p for commands without own completion]:completion function:->cfun:pattern' \
+  '(-d -p -P -K)-k[define widget and key binding]:completion function:->cfun:widget name::style:->style:*:key' \
+  '(-d -p -P -k)-K[define multiple widgets based on function]:completion function:->cfun:widget name::style:->style:*:key' \
+  '1:completion function:->cfun' \
+  '2:commands:_command_names'
+  
 
-if [ "$delete" ]; then
-  _wanted commands expl 'completed command' &&
-      compadd "$expl[@]" - ${(k)_comps}
-else
-  if [[ CURRENT -eq base ]]; then
-    _wanted functions expl 'completion function' &&
-        compadd "$expl[@]" - ${^fpath:/.}/_(|*[^~])(N:t)
-  else
-    _command_names
-  fi
-fi
+case $state in
+  ccom)
+    _wanted commands expl 'completed command' &&
+        compadd "$expl[@]" - ${(k)_comps}
+  ;;
+  cfun)
+    if _wanted functions expl 'completion function'; then
+      list=( ${^fpath:/.}/_(|*[^~])(N:t) )
+      if zstyle -T ":completion:${curcontext}" prefix-hidden; then
+        disp=( ${list[@]#_} )
+        compadd "$expl[@]" -d disp - "$list[@]"
+      else
+        compadd "$expl[@]" - "$list[@]"
+      fi
+    fi
+  ;;
+  style)
+    _wanted widgetstyle expl 'widget style' &&
+        compadd complete-word delete-char-or-list expand-or-complete \
+        expand-or-complete-prefix list-choices menu-complete \
+        menu-expand-or-complete reverse-menu-complete
+  ;;
+esac
diff --git a/Completion/Builtins/_zpty b/Completion/Builtins/_zpty
new file mode 100644
index 000000000..b197b4128
--- /dev/null
+++ b/Completion/Builtins/_zpty
@@ -0,0 +1,23 @@
+#compdef zpty
+
+local state line list names expl
+
+_arguments -C -s \
+  '(-d -w -r -L)-e[echo input characters]' \
+  '(-d -w -r -L)-b[io to pseudo-terminal blocking]' \
+  '(-e -b -w -r -L)-d[delete command]:*:name:->name' \
+  '(-e -b -d -r -L)-w[send string to command]:name:->name:*:strings to write' \
+  '(-e -b -d -w -L)-r[read string from command]:name:->name:param:_parameters:*:nothing:_nothing' \
+  '(-e -b -d -w -r)-L[list defined commands as calls]' \
+  '*::args:_normal'
+
+if [[ $state = name ]] && _wanted zptynames expl 'zpty command names'; then
+  list=( ${${(f)"$(zpty)"}#*\) } )
+  names=( ${list%%:*} )
+  if zstyle -T ":completion:${curcontext}" verbose; then
+    zformat -a list ' --' ${${(f)"$(zpty)"}#*\) }
+    compadd "$expl[@]" -d list - "$names[@]"
+  else
+    compadd "$expl[@]" - "$names[@]"
+  fi
+fi
diff --git a/Completion/User/_getconf b/Completion/User/_getconf
new file mode 100644
index 000000000..7ce709588
--- /dev/null
+++ b/Completion/User/_getconf
@@ -0,0 +1,37 @@
+#compdef getconf
+
+local expl
+
+if [[ CURRENT -eq 2 ]]; then
+  _tags syswideconfig pathconfig standardsconfig
+
+  while _tags; do
+    if _requested -V syswideconfig expl 'systemwide configuration variables'
+    then
+      compadd "$expl[@]" -S '' ARG_MAX BC_BASE_MAX BC_DIM_MAX BC_SCALE_MAX \
+          BC_STRING_MAX CHILD_MAX COLL_WEIGHTS_MAX EXPR_NEST_MAX LINE_MAX \
+	  NGROUPS_MAX OPEN_MAX RE_DUP_MAX STREAM_MAX TZNAME_MAX
+    fi
+    if _requested -V standardsconfig \
+        expl 'system-standards configuration variables'; then
+      compadd "$expl[@]" -S '' _POSIX_CHILD_MAX _POSIX_LINK_MAX \
+          _POSIX_MAX_CANON _POSIX_MAX_INPUT _POSIX_NAME_MAX _POSIX_NGROUPS_MAX \
+	  _POSIX_OPEN_MAX _POSIX_PATH_MAX _POSIX_PIPE_BUF _POSIX_SSIZE_MAX \
+	  _POSIX_STREAM_MAX _POSIX_TZNAME_MAX _POSIX_VERSION \
+	  POSIX2_BC_BASE_MAX POSIX2_BC_DIM_MAX POSIX2_BC_SCALE_MAX \
+	  POSIX2_BC_STRING_MAX POSIX2_COLL_WEIGHTS_MAX POSIX2_EXPR_NEST_MAX \
+	  POSIX2_LINE_MAX POSIX2_RE_DUP_MAX POSIX2_VERSION POSIX2_C_BIND \
+	  POSIX2_C_DEV POSIX2_FORT_DEV POSIX2_FORT_RUN POSIX2_LOCALEDEF \
+	  POSIX2_SW_DEV _XOPEN_VERSION
+    fi
+    if _requested -V pathconfig expl 'system path configuration variables'
+    then
+      compadd "$expl[@]" -S '' PIPE_BUF _POSIX_CHOWN_RESTRICTED \
+          _POSIX_NO_TRUNC _POSIX_VDISABLE
+      compadd "$expl[@]" -S ' ' LINK_MAX MAX_CANON MAX_INPUT NAME_MAX PATH_MAX \
+          PIPE_BUF
+    fi
+  done
+else
+  _files -/
+fi
-- 
cgit 1.4.1