From 2fa720395f4f2baa067798dadf710e623ce5253c Mon Sep 17 00:00:00 2001
From: Oliver Kiddle <opk@users.sourceforge.net>
Date: Mon, 6 Aug 2001 16:05:48 +0000
Subject: new completion for useradd, groupmod etc and fix in _cvs (15574)

---
 ChangeLog                           |  5 +++
 Completion/Unix/Command/_cvs        |  1 -
 Completion/Unix/Command/_user_admin | 67 +++++++++++++++++++++++++++++++++++++
 Completion/Unix/Type/_directories   |  3 ++
 Completion/Unix/Type/_groups        | 19 +++++++++++
 Completion/Unix/Type/_users         |  2 +-
 6 files changed, 95 insertions(+), 2 deletions(-)
 create mode 100644 Completion/Unix/Command/_user_admin
 create mode 100644 Completion/Unix/Type/_directories
 create mode 100644 Completion/Unix/Type/_groups

diff --git a/ChangeLog b/ChangeLog
index b97e8c125..570db11e5 100644
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,5 +1,10 @@
 2001-08-06  Oliver Kiddle  <opk@zsh.org>
 
+	* 15574: Completion/Unix/Command/_cvs, Completion/Unix/Type/_users,
+	Completion/Unix/Command/_user_admin, Completion/Unix/Type/_groups,
+	Completion/Unix/Type/_directories: new _user_admin completion for
+	useradd, groupmod etc and remove redundant duplication in _cvs
+
 	* 15562, Akinori Musha: 15559, 15563: Completion/BSD/Command/_chflags,
 	Completion/Unix/Command/_chown, Completion/Unix/Command/_sysctl:
 	new BSD completion and fix _chown for symlinks
diff --git a/Completion/Unix/Command/_cvs b/Completion/Unix/Command/_cvs
index 691407356..e01673fe7 100644
--- a/Completion/Unix/Command/_cvs
+++ b/Completion/Unix/Command/_cvs
@@ -163,7 +163,6 @@ _cvs_checkout () {
     '(-D)-r+[specify revision]:tag:_cvs_revisions' \
     '(-r)-D+[specify date]:date:_cvs_D' \
     '-j+[merge]:tag:_cvs_revisions' \
-    '-j+[merge]:tag:_cvs_revisions' \
     '*:module:_cvs_modules'
 }
 
diff --git a/Completion/Unix/Command/_user_admin b/Completion/Unix/Command/_user_admin
new file mode 100644
index 000000000..831f365b8
--- /dev/null
+++ b/Completion/Unix/Command/_user_admin
@@ -0,0 +1,67 @@
+#compdef useradd usermod groupadd groupmod
+
+local args shells home=${${words[(r)-D]:+b}:-d} sun=" -s"
+
+if [[ $service = user* ]]; then
+  if [[ -r /etc/shells ]]; then
+    shells=( $(</etc/shells) )
+  else
+    shells=( ${(M)commands:#*/(|[abckz]|tc|ba)sh} )
+  fi
+
+  args=(
+    '(-D)-c+[comment]:comment'
+    "(-D)-${home}+[home directory]:home directory:_directories -W /"
+    '(-D)-e+[specify expriration date]:expiration date (YYYY-MM-DD)'
+    '(-D)-f+[specify inactive days]:inactive days'
+    '(-D)-g+[initial group]:initial group:_groups'
+    '(-D)-G+[supplementary groups]:supplementary groups:_groups -S,'
+    "(-D)-s+[shell]:shell:( $shells /dev/null )"
+    '(-D)-m[create home directory]'
+    '(-D)-u[uid]:uid'
+    '(-D)-o[allow non unique uid]'
+  )
+  [[ $OSTYPE = linux* ]] && args=( $args[@] 
+      '(-D)-p+[specify encrypted password]:encrypted password' )
+
+  if [[ $service = useradd ]]; then
+    if [[ $OSTYPE = linux* ]]; then
+      args=( $args[@]
+	"(-D -k)-M[don't create home]"
+	'(-D)-r[create system account]'
+	"(-D)-n[don't create mirrored user]"
+      )
+      unset sun
+    fi
+    args=( $args[@]
+      "(-c -G -m -k -M -p -u -o -n -r$sun)-D[modify or display defaults]"
+      '(-D -M)-k[skeleton home directory]:skeleton directory:_directories -W /'
+      ':username'
+    )
+  else
+    [[ $OSTYPE = linux* ]] && args=( $args[@]
+	"(-U)-L[lock user's password]"
+	"(-L)-U[unlock user's password]"
+    )
+    args=( $args[@]
+      '-l[specify new user name]:new username'
+      ':username:_users'
+    )
+  fi
+else
+  args=( '-g+[gid]:gid' '-o[allow non unique gid]' )
+  if [[ $service = groupadd ]]; then
+    args=( $args[@] ':group name' )
+    [[ $OSTYPE = linux* ]] && args=( $args[@]
+      '-r[create system group]'
+      '-f[force]'
+    )
+  else
+    args=( $args[@] 
+      '-n[specify new group name]:new group name'
+      ':group name:_groups'
+    )
+  fi
+fi
+
+_arguments -A "-*" -s $args[@]
diff --git a/Completion/Unix/Type/_directories b/Completion/Unix/Type/_directories
new file mode 100644
index 000000000..9a1a9c1f3
--- /dev/null
+++ b/Completion/Unix/Type/_directories
@@ -0,0 +1,3 @@
+#compdef rmdir df du dircmp dirs
+
+_files -/ "$@"
diff --git a/Completion/Unix/Type/_groups b/Completion/Unix/Type/_groups
new file mode 100644
index 000000000..bbb80868b
--- /dev/null
+++ b/Completion/Unix/Type/_groups
@@ -0,0 +1,19 @@
+#compdef newgrp groupdel
+
+local expl groups tmp
+
+_tags groups || return 1
+
+if ! zstyle -a ":completion:${curcontext}:" groups groups; then
+  (( $+_cache_groups )) ||
+      if (( ${+commands[ypcat]} )) &&
+	  tmp=$(_call_program groups ypcat group.byname 2>/dev/null); then
+        : ${(A)_cache_groups:=${${(f)tmp}%%:*}} # If you use YP
+      else
+        : ${(A)_cache_groups:=${${(s: :)$(</etc/group)}%%:*}}
+      fi
+
+  groups=( "$_cache_groups[@]" )
+fi
+
+_wanted groups expl group compadd "$@" -a groups
diff --git a/Completion/Unix/Type/_users b/Completion/Unix/Type/_users
index 573d8fdb1..d04a16afe 100644
--- a/Completion/Unix/Type/_users
+++ b/Completion/Unix/Type/_users
@@ -1,4 +1,4 @@
-#compdef passwd groups
+#compdef passwd groups userdel
 
 local expl users
 
-- 
cgit 1.4.1