From 10fcc7eaaf99481df5bd0b8699b03aadf8ce466d Mon Sep 17 00:00:00 2001
From: Oliver Kiddle <okiddle@yahoo.co.uk>
Date: Thu, 5 Apr 2018 11:30:10 +0200
Subject: 42583: new column completion

---
 ChangeLog                       |  2 ++
 Completion/Unix/Command/_column | 59 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 61 insertions(+)
 create mode 100644 Completion/Unix/Command/_column

diff --git a/ChangeLog b/ChangeLog
index 27f85dc2b..65975d184 100644
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,5 +1,7 @@
 2018-04-05  Oliver Kiddle  <okiddle@yahoo.co.uk>
 
+	* 42583: Completion/Unix/Command/_column: new column completion
+
 	* 42582: Completion/BSD/Command/_cu, Completion/Unix/Command/_uniq,
 	Completion/Unix/Command/_dhclient, Completion/Unix/Command/_script:
 	updates to options in completions for OpenBSD 6.3
diff --git a/Completion/Unix/Command/_column b/Completion/Unix/Command/_column
new file mode 100644
index 000000000..cb67fef37
--- /dev/null
+++ b/Completion/Unix/Command/_column
@@ -0,0 +1,59 @@
+#compdef column
+
+local ret=1
+local -a context state line expl args columns MATCH
+local -i MBEGIN MEND
+local -A opt_args
+
+case $OSTYPE in
+  linux-gnu)
+    args=(
+      '(info json -c --output-width)'{-c+,--output-width=}'[format output to fit display of specified width]:width'
+      + fill
+      '(info table text json -x --fillrows)'{-x,--fillrows}'[fill rows before filling columns]'
+      + table
+      '(info fill -t --table)'{-t,--table}'[create a table]'
+      '(info fill -s --separator)'{-s+,--separator=}'[specify column delimiters in input data]:delimiters'
+      '(info fill -O --table-order)'{-O+,--table-order=}'[specify order of output columns]: :->columns'
+      '(info fill -N --table-columns)'{-N+,--table-columns=}'[specify column names]:names'
+      '(info fill -H --table-hide)'{-H+,--table-hide=}"[don't print specified columns]: :->columns"
+      + text
+      '(info fill json -d --table-noheadings)'{-d,--table-noheadings}"[don't print header]"
+      '(info fill json -E --table-noextreme)'{-E,--table-noextreme}"[specify columns where length can be ignored]: :->columns"
+      '(info fill json -e --table-header-repeat)'{-e,--table-header-repeat}'[repeat header for each page]'
+      '(info fill json -R --table-right)'{-R+,--table-right=}'[right align text in these columns]: :->columns'
+      '(info fill json -T --table-truncate)'{-T+,--table-truncate=}'[truncate text in the columns when necessary]: :->columns'
+      '(info fill json -W --table-wrap)'{-W+,--table-wrap=}'[wrap text in the columns when necessary]: :->columns'
+      '(info fill json -r --tree)'{-r+,--tree=}'[specify column to format tree-like]: :->column'
+      '(info fill json -i --tree-id)'{-i+,--tree-id=}'[specify column containing ID for child-parent relations]: :->column'
+      '(info fill json -p --tree-parent)'{-p+,--tree-parent=}'[specify column containing reference to parent]: :->column'
+      + json
+      '(info fill text -n --table-name -c --output-width)'{-n+,--table-name=}'[specify table name for JSON output]:name'
+      '(info fill text -J --json -c --output-width)'{-J,--json}'[use JSON output format for table]'
+      + info
+      '(- *)'{-h,--help}'[display usage information]'
+      '(- *)'{-V,--version}'[display version information]'
+    )
+  ;;
+  *)
+    args=(
+      '(-t -s)-c+[format output to fit display of specified width]:width'
+      '(-c -x)-t[create a table]'
+      '(-c -x)-s+[specify column delimiters in input data]:delimiters'
+      '(-t -s)-x[fill rows before filling columns]'
+    )
+  ;;
+esac
+
+_arguments -s -S '*:file:_files' $args && ret=0
+
+if [[ -n $state ]]; then
+  columns=( ${(s.,.)${(Q)${opt_args[table--N]:-$opt_args[table---table-columns]}//(#m)\\([\\:])/${MATCH[2]}}} )
+  if (( $#columns )); then
+    ${${(M)state:#*s}:+_sequence} _wanted -C "$context[1]" columns expl column compadd -a - columns && ret=0
+  else
+    _message -e columns "$state"
+  fi
+fi
+
+return ret
-- 
cgit 1.4.1