1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
|
/* Optimized wcslen for x86-64 with SSE2.
Copyright (C) 2011-2013 Free Software Foundation, Inc.
Contributed by Intel Corporation.
This file is part of the GNU C Library.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, see
<http://www.gnu.org/licenses/>. */
#include <sysdep.h>
.text
ENTRY (__wcslen)
#ifdef __CHKP__
bndcl (%rdi), %bnd0
bndcu (%rdi), %bnd0
#endif
cmpl $0, (%rdi)
jz L(exit_tail0)
#ifdef __CHKP__
bndcu 4(%rdi), %bnd0
#endif
cmpl $0, 4(%rdi)
jz L(exit_tail1)
#ifdef __CHKP__
bndcu 8(%rdi), %bnd0
#endif
cmpl $0, 8(%rdi)
jz L(exit_tail2)
#ifdef __CHKP__
bndcu 12(%rdi), %bnd0
#endif
cmpl $0, 12(%rdi)
jz L(exit_tail3)
#ifdef __CHKP__
bndcu 16(%rdi), %bnd0
#endif
cmpl $0, 16(%rdi)
jz L(exit_tail4)
#ifdef __CHKP__
bndcu 20(%rdi), %bnd0
#endif
cmpl $0, 20(%rdi)
jz L(exit_tail5)
#ifdef __CHKP__
bndcu 24(%rdi), %bnd0
#endif
cmpl $0, 24(%rdi)
jz L(exit_tail6)
#ifdef __CHKP__
bndcu 28(%rdi), %bnd0
#endif
cmpl $0, 28(%rdi)
jz L(exit_tail7)
pxor %xmm0, %xmm0
lea 32(%rdi), %rax
lea 16(%rdi), %rcx
and $-16, %rax
#ifdef __CHKP__
bndcu (%rax), %bnd0
#endif
pcmpeqd (%rax), %xmm0
pmovmskb %xmm0, %edx
pxor %xmm1, %xmm1
test %edx, %edx
lea 16(%rax), %rax
jnz L(exit)
#ifdef __CHKP__
bndcu (%rax), %bnd0
#endif
pcmpeqd (%rax), %xmm1
pmovmskb %xmm1, %edx
pxor %xmm2, %xmm2
test %edx, %edx
lea 16(%rax), %rax
jnz L(exit)
#ifdef __CHKP__
bndcu (%rax), %bnd0
#endif
pcmpeqd (%rax), %xmm2
pmovmskb %xmm2, %edx
pxor %xmm3, %xmm3
test %edx, %edx
lea 16(%rax), %rax
jnz L(exit)
#ifdef __CHKP__
bndcu (%rax), %bnd0
#endif
pcmpeqd (%rax), %xmm3
pmovmskb %xmm3, %edx
test %edx, %edx
lea 16(%rax), %rax
jnz L(exit)
#ifdef __CHKP__
bndcu (%rax), %bnd0
#endif
pcmpeqd (%rax), %xmm0
pmovmskb %xmm0, %edx
test %edx, %edx
lea 16(%rax), %rax
jnz L(exit)
#ifdef __CHKP__
bndcu (%rax), %bnd0
#endif
pcmpeqd (%rax), %xmm1
pmovmskb %xmm1, %edx
test %edx, %edx
lea 16(%rax), %rax
jnz L(exit)
#ifdef __CHKP__
bndcu (%rax), %bnd0
#endif
pcmpeqd (%rax), %xmm2
pmovmskb %xmm2, %edx
test %edx, %edx
lea 16(%rax), %rax
jnz L(exit)
#ifdef __CHKP__
bndcu (%rax), %bnd0
#endif
pcmpeqd (%rax), %xmm3
pmovmskb %xmm3, %edx
test %edx, %edx
lea 16(%rax), %rax
jnz L(exit)
#ifdef __CHKP__
bndcu (%rax), %bnd0
#endif
pcmpeqd (%rax), %xmm0
pmovmskb %xmm0, %edx
test %edx, %edx
lea 16(%rax), %rax
jnz L(exit)
#ifdef __CHKP__
bndcu (%rax), %bnd0
#endif
pcmpeqd (%rax), %xmm1
pmovmskb %xmm1, %edx
test %edx, %edx
lea 16(%rax), %rax
jnz L(exit)
#ifdef __CHKP__
bndcu (%rax), %bnd0
#endif
pcmpeqd (%rax), %xmm2
pmovmskb %xmm2, %edx
test %edx, %edx
lea 16(%rax), %rax
jnz L(exit)
#ifdef __CHKP__
bndcu (%rax), %bnd0
#endif
pcmpeqd (%rax), %xmm3
pmovmskb %xmm3, %edx
test %edx, %edx
lea 16(%rax), %rax
jnz L(exit)
and $-0x40, %rax
.p2align 4
L(aligned_64_loop):
#ifdef __CHKP__
bndcu (%rax), %bnd0
#endif
movaps (%rax), %xmm0
movaps 16(%rax), %xmm1
movaps 32(%rax), %xmm2
movaps 48(%rax), %xmm6
pminub %xmm1, %xmm0
pminub %xmm6, %xmm2
pminub %xmm0, %xmm2
pcmpeqd %xmm3, %xmm2
pmovmskb %xmm2, %edx
test %edx, %edx
lea 64(%rax), %rax
jz L(aligned_64_loop)
pcmpeqd -64(%rax), %xmm3
pmovmskb %xmm3, %edx
test %edx, %edx
lea 48(%rcx), %rcx
jnz L(exit)
pcmpeqd %xmm1, %xmm3
pmovmskb %xmm3, %edx
test %edx, %edx
lea -16(%rcx), %rcx
jnz L(exit)
pcmpeqd -32(%rax), %xmm3
pmovmskb %xmm3, %edx
test %edx, %edx
lea -16(%rcx), %rcx
jnz L(exit)
pcmpeqd %xmm6, %xmm3
pmovmskb %xmm3, %edx
test %edx, %edx
lea -16(%rcx), %rcx
jnz L(exit)
jmp L(aligned_64_loop)
.p2align 4
L(exit):
sub %rcx, %rax
shr $2, %rax
test %dl, %dl
jz L(exit_high)
mov %dl, %cl
and $15, %cl
jz L(exit_1)
#ifdef __CHKP__
bndcu -1(%rdi, %rax, 4), %bnd0
#endif
ret
.p2align 4
L(exit_high):
mov %dh, %ch
and $15, %ch
jz L(exit_3)
add $2, %rax
#ifdef __CHKP__
bndcu -1(%rdi, %rax, 4), %bnd0
#endif
ret
.p2align 4
L(exit_1):
add $1, %rax
#ifdef __CHKP__
bndcu -1(%rdi, %rax, 4), %bnd0
#endif
ret
.p2align 4
L(exit_3):
add $3, %rax
ret
.p2align 4
L(exit_tail0):
xor %rax, %rax
ret
.p2align 4
L(exit_tail1):
mov $1, %rax
ret
.p2align 4
L(exit_tail2):
mov $2, %rax
ret
.p2align 4
L(exit_tail3):
mov $3, %rax
ret
.p2align 4
L(exit_tail4):
mov $4, %rax
ret
.p2align 4
L(exit_tail5):
mov $5, %rax
ret
.p2align 4
L(exit_tail6):
mov $6, %rax
ret
.p2align 4
L(exit_tail7):
mov $7, %rax
ret
END (__wcslen)
weak_alias(__wcslen, wcslen)
|
