1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
|
/* Optimized strspn implementation for PowerPC64/POWER7.
Copyright (C) 2014 Free Software Foundation, Inc.
This file is part of the GNU C Library.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, see
<http://www.gnu.org/licenses/>. */
/* size_t [r3] strspn (const char *string [r3],
const char *needleAccept [r4] */
/* Performance gains are grabbed through following techniques:
> hashing of needle.
> hashing avoids scanning of duplicate entries in needle
across the string.
> initializing the hash table with Vector instructions
by quadword access.
> unrolling when scanning for character in string
across hash table. */
/* Algorithm is as below:
1. A empty hash table/dictionary is created comprising of
256 ascii character set
2. When hash entry is found in needle , the hash index
is initialized to 1
3. The string is scanned until end and for every character,
its corresponding hash index is compared.
4. initial length of string (count) until first hit of
accept needle to be found is set to 0
4. If hash index is set to 1 for the index of string,
count is returned.
5. Otherwise count is incremented and scanning continues
until end of string. */
#include <sysdep.h>
#undef strspn
.machine power7
EALIGN(strspn, 4, 0)
CALL_MCOUNT 2
lbz r10, 0(r4) /* load r10 with needle (r4) */
addi r9, r1, -256 /* r9 is a hash of 256 bytes */
li r5, 16 /* set r5 = 16 as offset */
li r6, 32 /* set r6 = 32 as offset */
li r8, 48 /* set r8 = 48 as offset */
/*Iniatliaze hash table with Zeroes in double indexed quadword accesses */
xxlxor v0, v0, v0 /* prepare for initializing hash */
stxvd2x v0, r0, r9 /* initialize 1st quadword */
stxvd2x v0, r9, r5
stxvd2x v0, r9, r6
stxvd2x v0, r9, r8 /* initialize 4th quadword */
addi r11, r9, 64 /* r11 is index to hash */
stxvd2x v0, r0, r11 /* initialize 5th quadword */
stxvd2x v0, r11, r5
stxvd2x v0, r11, r6
stxvd2x v0, r11, r8 /* initialize 8th quadword */
addi r11, r9, 128 /* r11 is index to hash */
stxvd2x v0, r0, r11 /* initialize 9th quadword */
stxvd2x v0, r11, r5
stxvd2x v0, r11, r6
stxvd2x v0, r11, r8 /* initialize 12th quadword */
addi r11, r9, 192 /* r11 is index to hash */
stxvd2x v0, r0, r11 /* initialize 13th quadword */
stxvd2x v0, r11, r5
stxvd2x v0, r11, r6
stxvd2x v0, r11, r8 /* initialize 16th quadword */
li r8, 1 /* r8=1, marker into hash if found in
needle */
cmpdi cr7, r10, 0 /* accept needle is NULL */
beq cr7, L(skipHashing) /* if needle is NULL, skip hashing */
.p2align 4 /* align section to 16 byte boundary */
L(hashing):
stbx r8, r9, r10 /* update hash with marker for the pivot of
the needle */
lbzu r10, 1(r4) /* load needle into r10 and update to next */
cmpdi cr7, r10, 0 /* if needle is has reached NULL, continue */
bne cr7, L(hashing) /* loop to hash the needle */
L(skipHashing):
li r10, 0 /* load counter = 0 */
b L(beginScan)
.p2align 4 /* align section to 16 byte boundary */
L(scanUnroll):
lbzx r8, r9, r8 /* load r8 with hash value at index */
cmpwi cr7, r8, 0 /* if we hit marker in hash, we have found
accept needle */
beq cr7, L(ret1stIndex) /* we have hit accept needle, return the
count */
lbz r8, 1(r3) /* load string[1] into r8 */
addi r10, r10, 4 /* increment counter */
lbzx r8, r9, r8 /* load r8 with hash value at index */
cmpwi cr7, r8, 0 /* if we hit marker in hash, we have found
accept needle */
beq cr7, L(ret2ndIndex) /* we have hit accept needle, return the
count */
lbz r8, 2(r3) /* load string[2] into r8 */
lbzx r8, r9, r8 /* load r8 with hash value at index */
cmpwi cr7, r8, 0 /* if we hit marker in hash, we have found
accept needle */
beq cr7, L(ret3rdIndex) /* we have hit accept needle, return the
count */
lbz r8, 3(r3) /* load string[3] into r8 */
lbzx r8, r9, r8 /* load r8 with hash value at index */
addi r3, r3, 4 /* unroll factor , increment string by 4 */
cmpwi cr7, r8, 0 /* if we hit marker in hash, we have found
accept needle */
beq cr7,L(ret4thIndex) /* we have hit accept needle, return the
count */
L(beginScan):
lbz r8, 0(r3) /* load string[0] into r8 */
addi r6, r10, 1 /* place holder for counter + 1 */
addi r5, r10, 2 /* place holder for counter + 2 */
addi r4, r10, 3 /* place holder for counter + 3 */
cmpdi cr7, r8, 0 /* if we hit marker in hash, we have found
accept needle */
bne cr7, L(scanUnroll) /* continue scanning */
L(ret1stIndex):
mr r3, r10 /* update r3 for return */
blr /* return */
L(ret2ndIndex):
mr r3, r6 /* update r3 for return */
blr /* return */
L(ret3rdIndex):
mr r3, r5 /* update r3 for return */
blr /* return */
L(ret4thIndex):
mr r3, r4 /* update r3 for return */
blr /* done */
END(strspn)
libc_hidden_builtin_def (strspn)
|
