1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
|
/* Optimized memcmp implementation using LoongArch LSX instructions.
Copyright (C) 2023-2024 Free Software Foundation, Inc.
This file is part of the GNU C Library.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library. If not, see
<https://www.gnu.org/licenses/>. */
#include <sysdep.h>
#include <sys/regdef.h>
#include <sys/asm.h>
#if IS_IN (libc) && !defined __loongarch_soft_float
#define MEMCMP __memcmp_lsx
LEAF(MEMCMP, 6)
beqz a2, L(out)
pcalau12i t0, %pc_hi20(L(INDEX))
andi a3, a0, 0xf
vld vr5, t0, %pc_lo12(L(INDEX))
andi a4, a1, 0xf
bne a3, a4, L(unaligned)
bstrins.d a0, zero, 3, 0
xor a1, a1, a4
vld vr0, a0, 0
vld vr1, a1, 0
li.d t0, 16
vreplgr2vr.b vr3, a3
sub.d t1, t0, a3
vadd.b vr3, vr3, vr5
vshuf.b vr0, vr3, vr0, vr3
vshuf.b vr1, vr3, vr1, vr3
vseq.b vr4, vr0, vr1
bgeu t1, a2, L(al_end)
vsetanyeqz.b fcc0, vr4
bcnez fcc0, L(al_found)
sub.d t1, a2, t1
andi a2, t1, 31
beq a2, t1, L(al_less_32bytes)
sub.d t2, t1, a2
add.d a4, a0, t2
L(al_loop):
vld vr0, a0, 16
vld vr1, a1, 16
vld vr2, a0, 32
vld vr3, a1, 32
addi.d a0, a0, 32
addi.d a1, a1, 32
vseq.b vr4, vr0, vr1
vseq.b vr6, vr2, vr3
vand.v vr6, vr4, vr6
vsetanyeqz.b fcc0, vr6
bcnez fcc0, L(al_pair_end)
bne a0, a4, L(al_loop)
L(al_less_32bytes):
bgeu t0, a2, L(al_less_16bytes)
vld vr0, a0, 16
vld vr1, a1, 16
vld vr2, a0, 32
vld vr3, a1, 32
addi.d a2, a2, -16
vreplgr2vr.b vr6, a2
vslt.b vr5, vr5, vr6
vseq.b vr4, vr0, vr1
vseq.b vr6, vr2, vr3
vorn.v vr6, vr6, vr5
L(al_pair_end):
vsetanyeqz.b fcc0, vr4
bcnez fcc0, L(al_found)
vnori.b vr4, vr6, 0
vfrstpi.b vr4, vr4, 0
vshuf.b vr0, vr2, vr2, vr4
vshuf.b vr1, vr3, vr3, vr4
vpickve2gr.bu t0, vr0, 0
vpickve2gr.bu t1, vr1, 0
sub.d a0, t0, t1
jr ra
nop
nop
L(al_less_16bytes):
beqz a2, L(out)
vld vr0, a0, 16
vld vr1, a1, 16
vseq.b vr4, vr0, vr1
L(al_end):
vreplgr2vr.b vr6, a2
vslt.b vr5, vr5, vr6
vorn.v vr4, vr4, vr5
nop
L(al_found):
vnori.b vr4, vr4, 0
vfrstpi.b vr4, vr4, 0
vshuf.b vr0, vr0, vr0, vr4
vshuf.b vr1, vr1, vr1, vr4
vpickve2gr.bu t0, vr0, 0
vpickve2gr.bu t1, vr1, 0
sub.d a0, t0, t1
jr ra
L(out):
move a0, zero
jr ra
nop
nop
L(unaligned):
xor t2, a0, a1
sltu a5, a3, a4
masknez t2, t2, a5
xor a0, a0, t2
xor a1, a1, t2
andi a3, a0, 0xf
andi a4, a1, 0xf
bstrins.d a0, zero, 3, 0
xor a1, a1, a4
vld vr4, a0, 0
vld vr1, a1, 0
li.d t0, 16
vreplgr2vr.b vr2, a4
sub.d a6, a4, a3
sub.d t1, t0, a4
sub.d t2, t0, a6
vadd.b vr2, vr2, vr5
vreplgr2vr.b vr6, t2
vadd.b vr6, vr6, vr5
vshuf.b vr0, vr4, vr4, vr6
vshuf.b vr1, vr2, vr1, vr2
vshuf.b vr0, vr2, vr0, vr2
vseq.b vr7, vr0, vr1
bgeu t1, a2, L(un_end)
vsetanyeqz.b fcc0, vr7
bcnez fcc0, L(un_found)
sub.d a2, a2, t1
andi t1, a2, 31
beq a2, t1, L(un_less_32bytes)
sub.d t2, a2, t1
move a2, t1
add.d a4, a1, t2
L(un_loop):
vld vr2, a0, 16
vld vr1, a1, 16
vld vr3, a1, 32
addi.d a1, a1, 32
addi.d a0, a0, 32
vshuf.b vr0, vr2, vr4, vr6
vld vr4, a0, 0
vseq.b vr7, vr0, vr1
vshuf.b vr2, vr4, vr2, vr6
vseq.b vr8, vr2, vr3
vand.v vr8, vr7, vr8
vsetanyeqz.b fcc0, vr8
bcnez fcc0, L(un_pair_end)
bne a1, a4, L(un_loop)
L(un_less_32bytes):
bltu a2, t0, L(un_less_16bytes)
vld vr2, a0, 16
vld vr1, a1, 16
addi.d a0, a0, 16
addi.d a1, a1, 16
addi.d a2, a2, -16
vshuf.b vr0, vr2, vr4, vr6
vor.v vr4, vr2, vr2
vseq.b vr7, vr0, vr1
vsetanyeqz.b fcc0, vr7
bcnez fcc0, L(un_found)
L(un_less_16bytes):
beqz a2, L(out)
vld vr1, a1, 16
bgeu a6, a2, 1f
vld vr2, a0, 16
1:
vshuf.b vr0, vr2, vr4, vr6
vseq.b vr7, vr0, vr1
L(un_end):
vreplgr2vr.b vr3, a2
vslt.b vr3, vr5, vr3
vorn.v vr7, vr7, vr3
L(un_found):
vnori.b vr7, vr7, 0
vfrstpi.b vr7, vr7, 0
vshuf.b vr0, vr0, vr0, vr7
vshuf.b vr1, vr1, vr1, vr7
L(calc_result):
vpickve2gr.bu t0, vr0, 0
vpickve2gr.bu t1, vr1, 0
sub.d t2, t0, t1
sub.d t3, t1, t0
masknez t0, t3, a5
maskeqz t1, t2, a5
or a0, t0, t1
jr ra
L(un_pair_end):
vsetanyeqz.b fcc0, vr7
bcnez fcc0, L(un_found)
vnori.b vr7, vr8, 0
vfrstpi.b vr7, vr7, 0
vshuf.b vr0, vr2, vr2, vr7
vshuf.b vr1, vr3, vr3, vr7
b L(calc_result)
END(MEMCMP)
.section .rodata.cst16,"M",@progbits,16
.align 4
L(INDEX):
.dword 0x0706050403020100
.dword 0x0f0e0d0c0b0a0908
libc_hidden_builtin_def (MEMCMP)
#endif
|
