1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
|
/* Compute cubic root of double value.
Copyright (C) 1997 Free Software Foundation, Inc.
This file is part of the GNU C Library.
Contributed by Dirk Alboth <dirka@uni-paderborn.de> and
Ulrich Drepper <drepper@cygnus.com>, 1997.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Library General Public License as
published by the Free Software Foundation; either version 2 of the
License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Library General Public License for more details.
You should have received a copy of the GNU Library General Public
License along with the GNU C Library; see the file COPYING.LIB. If not,
write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
Boston, MA 02111-1307, USA. */
#include <machine/asm.h>
#ifdef __ELF__
.section .rodata
#else
.text
#endif
.align ALIGNARG(4)
ASM_TYPE_DIRECTIVE(f1,@object)
f1: .double 0.354895765043919860
ASM_SIZE_DIRECTIVE(f1)
ASM_TYPE_DIRECTIVE(f2,@object)
f2: .double 1.50819193781584896
ASM_SIZE_DIRECTIVE(f2)
ASM_TYPE_DIRECTIVE(f3,@object)
f3: .double -2.11499494167371287
ASM_SIZE_DIRECTIVE(f3)
ASM_TYPE_DIRECTIVE(f4,@object)
f4: .double 2.44693122563534430
ASM_SIZE_DIRECTIVE(f4)
ASM_TYPE_DIRECTIVE(f5,@object)
f5: .double -1.83469277483613086
ASM_SIZE_DIRECTIVE(f5)
ASM_TYPE_DIRECTIVE(f6,@object)
f6: .double 0.784932344976639262
ASM_SIZE_DIRECTIVE(f6)
ASM_TYPE_DIRECTIVE(f7,@object)
f7: .double -0.145263899385486377
ASM_SIZE_DIRECTIVE(f7)
#define CBRT2 1.2599210498948731648
#define SQR_CBRT2 1.5874010519681994748
ASM_TYPE_DIRECTIVE(factor,@object)
factor: .double 1.0 / SQR_CBRT2
.double 1.0 / CBRT2
.double 1.0
.double CBRT2
.double SQR_CBRT2
ASM_SIZE_DIRECTIVE(factor)
ASM_TYPE_DIRECTIVE(two54,@object)
two54: .byte 0, 0, 0, 0, 0, 0, 0x50, 0x43
ASM_SIZE_DIRECTIVE(two54)
#ifdef PIC
#define MO(op) op##@GOTOFF(%ebx)
#define MOX(op,x,f) op##@GOTOFF(%ebx,x,f)
#else
#define MO(op) op
#define MOX(op,x,f) op(,x,f)
#endif
.text
ENTRY(__cbrt)
movl 4(%esp), %ecx
movl 8(%esp), %eax
movl %eax, %edx
andl $0x7fffffff, %eax
orl %eax, %ecx
jz 1f
xorl %ecx, %ecx
cmpl $0x7ff00000, %eax
jae 1f
#ifdef PIC
pushl %ebx
call 3f
3: popl %ebx
addl $_GLOBAL_OFFSET_TABLE_+[.-3b], %ebx
#endif
cmpl $0x00100000, %eax
jae 2f
#ifdef PIC
fldl 8(%esp)
#else
fldl 4(%esp)
#endif
fmull MO(two54)
movl $-54, %ecx
fstpl 4(%esp)
movl 8(%esp), %eax
movl %eax, %edx
andl $0x7fffffff, %eax
2: shrl $20, %eax
andl $0x800fffff, %edx
subl $1022, %eax
orl $0x3fe00000, %edx
addl %eax, %ecx
#ifdef PIC
movl %edx, 12(%esp)
fldl 8(%esp) /* xm */
#else
movl %edx, 8(%esp)
fldl 4(%esp) /* xm */
#endif
fabs
/* The following code has two track:
a) compute the normalized cbrt value
b) compute xe/3 and xe%3
The right track computes the value for b) and this is done
in an optimized way by avoiding division. */
fld %st(0) /* xm : xm */
fmull MO(f7) /* f7*xm : xm */
movl $1431655766, %eax
faddl MO(f6) /* f6+f7*xm : xm */
imull %ecx
fmul %st(1) /* (f6+f7*xm)*xm : xm */
movl %ecx, %eax
faddl MO(f5) /* f5+(f6+f7*xm)*xm : xm */
sarl $31, %eax
fmul %st(1) /* (f5+(f6+f7*xm)*xm)*xm : xm */
subl %eax, %edx
faddl MO(f4) /* f4+(f5+(f6+f7*xm)*xm)*xm : xm */
fmul %st(1) /* (f4+(f5+(f6+f7*xm)*xm)*xm)*xm : xm */
faddl MO(f3) /* f3+(f4+(f5+(f6+f7*xm)*xm)*xm)*xm : xm */
fmul %st(1) /* (f3+(f4+(f5+(f6+f7*xm)*xm)*xm)*xm)*xm : xm */
faddl MO(f2) /* f2+(f3+(f4+(f5+(f6+f7*xm)*xm)*xm)*xm)*xm : xm */
fmul %st(1) /* (f2+(f3+(f4+(f5+(f6+f7*xm)*xm)*xm)*xm)*xm)*xm : xm */
faddl MO(f1) /* u:=f1+(f2+(f3+(f4+(f5+(f6+f7*xm)*xm)*xm)*xm)*xm)*xm : xm */
fld %st /* u : u : xm */
fmul %st(1) /* u*u : u : xm */
fld %st(2) /* xm : u*u : u : xm */
fadd %st /* 2*xm : u*u : u : xm */
fxch %st(1) /* u*u : 2*xm : u : xm */
fmul %st(2) /* t2:=u*u*u : 2*xm : u : xm */
movl %edx, %eax
fadd %st, %st(1) /* t2 : t2+2*xm : u : xm */
leal (%edx,%edx,2),%edx
fadd %st(0) /* 2*t2 : t2+2*xm : u : xm */
subl %edx, %ecx
faddp %st, %st(3) /* t2+2*xm : u : 2*t2+xm */
fmulp /* u*(t2+2*xm) : 2*t2+xm */
fdivp %st, %st(1) /* u*(t2+2*xm)/(2*t2+xm) */
fmull MOX(16+factor,%ecx,8) /* u*(t2+2*xm)/(2*t2+xm)*FACT */
pushl %eax
fildl (%esp) /* xe/3 : u*(t2+2*xm)/(2*t2+xm)*FACT */
fxch /* u*(t2+2*xm)/(2*t2+xm)*FACT : xe/3 */
popl %eax
fscale /* u*(t2+2*xm)/(2*t2+xm)*FACT*2^xe/3 */
fstp %st(1)
#ifdef PIC
popl %ebx
#endif
testl $0x80000000, 8(%esp)
jz 4f
fchs
4: ret
/* Return the argument. */
1: fldl 4(%esp)
ret
END(__cbrt)
weak_alias (__cbrt, cbrt)
|
