1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
/* memset/bzero -- set memory area to CH/0
Highly optimized version for ix86, x>=6.
Copyright (C) 1999 Free Software Foundation, Inc.
This file is part of the GNU C Library.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Library General Public License as
published by the Free Software Foundation; either version 2 of the
License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Library General Public License for more details.
You should have received a copy of the GNU Library General Public
License along with the GNU C Library; see the file COPYING.LIB. If not,
write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
Boston, MA 02111-1307, USA. */
#include <sysdep.h>
#include "asm-syntax.h"
/*
INPUT PARAMETERS:
(memset) (bzero)
dst (sp + 4) dst (sp + 4)
ch (sp + 8) len (sp + 8)
len (sp + 12)
*/
.text
ENTRY (memset)
cld
pushl %edi
movl 8(%esp), %edx
#ifdef memset
movl 12(%esp), %ecx
xorl %eax, %eax
#else
movzbl 12(%esp), %eax
movl 16(%esp), %ecx
#endif
jecxz 1f
movl %edx, %edi
andl $3, %edx
jz 2f
jnp 3f
stosb
decl %ecx
jz 1f
3: stosb
decl %ecx
jz 1f
xorl $3, %edx
jz 2f
stosb
decl %ecx
2: movl %ecx, %edx
shrl $2, %ecx
andl $3, %edx
#ifndef memset
imul $0x01010101, %eax
#endif
rep
stosl
movl %edx, %ecx
rep
stosb
1: movl 8(%esp), %eax
popl %edi
ret
END (memset)
|
