1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
/* memset/bzero -- set memory area to CH/0
Highly optimized version for ix86, x>=6.
Copyright (C) 1999-2024 Free Software Foundation, Inc.
This file is part of the GNU C Library.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, see
<https://www.gnu.org/licenses/>. */
#include <sysdep.h>
#include "asm-syntax.h"
#define PARMS 4+4 /* space for 1 saved reg */
#define RTN PARMS
#define DEST RTN
#define CHR DEST+4
#define LEN CHR+4
.text
#if defined PIC && IS_IN (libc)
ENTRY_CHK (__memset_chk)
movl 12(%esp), %eax
cmpl %eax, 16(%esp)
jb HIDDEN_JUMPTARGET (__chk_fail)
END_CHK (__memset_chk)
libc_hidden_builtin_def (__memset_chk)
#endif
ENTRY (memset)
cld
pushl %edi
cfi_adjust_cfa_offset (4)
movl DEST(%esp), %edx
movl LEN(%esp), %ecx
movzbl CHR(%esp), %eax
jecxz 1f
movl %edx, %edi
cfi_rel_offset (edi, 0)
andl $3, %edx
jz 2f /* aligned */
jp 3f /* misaligned at 3, store just one byte below */
stosb /* misaligned at 1 or 2, store two bytes */
decl %ecx
jz 1f
3: stosb
decl %ecx
jz 1f
xorl $1, %edx
jnz 2f /* was misaligned at 2 or 3, now aligned */
stosb /* was misaligned at 1, store third byte */
decl %ecx
2: movl %ecx, %edx
shrl $2, %ecx
andl $3, %edx
imul $0x01010101, %eax
rep
stosl
movl %edx, %ecx
rep
stosb
1:
movl DEST(%esp), %eax /* start address of destination is result */
popl %edi
cfi_adjust_cfa_offset (-4)
cfi_restore (edi)
ret
END (memset)
libc_hidden_builtin_def (memset)
|
