1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
|
/* Helper macros for x86 libm functions.
Copyright (C) 2015-2019 Free Software Foundation, Inc.
This file is part of the GNU C Library.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, see
<https://www.gnu.org/licenses/>. */
#ifndef _I386_MATH_ASM_H
#define _I386_MATH_ASM_H 1
/* Remove excess range and precision by storing a value on the stack
and loading it back. */
#define FLT_NARROW_EVAL \
subl $4, %esp; \
cfi_adjust_cfa_offset (4); \
fstps (%esp); \
flds (%esp); \
addl $4, %esp; \
cfi_adjust_cfa_offset (-4);
#define DBL_NARROW_EVAL \
subl $8, %esp; \
cfi_adjust_cfa_offset (8); \
fstpl (%esp); \
fldl (%esp); \
addl $8, %esp; \
cfi_adjust_cfa_offset (-8);
/* Define constants for the minimum value of a floating-point
type. */
#define DEFINE_FLT_MIN \
.section .rodata.cst4,"aM",@progbits,4; \
.p2align 2; \
.type flt_min,@object; \
flt_min: \
.byte 0, 0, 0x80, 0; \
.size flt_min, .-flt_min;
#define DEFINE_DBL_MIN \
.section .rodata.cst8,"aM",@progbits,8; \
.p2align 3; \
.type dbl_min,@object; \
dbl_min: \
.byte 0, 0, 0, 0, 0, 0, 0x10, 0; \
.size dbl_min, .-dbl_min;
#define DEFINE_LDBL_MIN \
.section .rodata.cst16,"aM",@progbits,16; \
.p2align 4; \
.type ldbl_min,@object; \
ldbl_min: \
.byte 0, 0, 0, 0, 0, 0, 0, 0x80, 0x1, 0; \
.byte 0, 0, 0, 0, 0, 0; \
.size ldbl_min, .-ldbl_min;
/* Remove excess range and precision by storing a value on the stack
and loading it back. The value is given to be nonnegative or NaN;
if it is subnormal, also force an underflow exception. The
relevant constant for the minimum of the type must have been
defined, the MO macro must have been defined for access to memory
operands, and, if PIC, the PIC register must have been loaded. */
#define FLT_NARROW_EVAL_UFLOW_NONNEG_NAN \
subl $4, %esp; \
cfi_adjust_cfa_offset (4); \
flds MO(flt_min); \
fld %st(1); \
fucompp; \
fnstsw; \
sahf; \
jnc 6424f; \
fld %st(0); \
fmul %st(0); \
fstps (%esp); \
6424: fstps (%esp); \
flds (%esp); \
addl $4, %esp; \
cfi_adjust_cfa_offset (-4);
#define DBL_NARROW_EVAL_UFLOW_NONNEG_NAN \
subl $8, %esp; \
cfi_adjust_cfa_offset (8); \
fldl MO(dbl_min); \
fld %st(1); \
fucompp; \
fnstsw; \
sahf; \
jnc 6453f; \
fld %st(0); \
fmul %st(0); \
fstpl (%esp); \
6453: fstpl (%esp); \
fldl (%esp); \
addl $8, %esp; \
cfi_adjust_cfa_offset (-8);
/* Likewise, but the argument is not a NaN (so fcom instructions,
which support memory operands, can be used). */
#define FLT_NARROW_EVAL_UFLOW_NONNEG \
subl $4, %esp; \
cfi_adjust_cfa_offset (4); \
fcoms MO(flt_min); \
fnstsw; \
sahf; \
jnc 6424f; \
fld %st(0); \
fmul %st(0); \
fstps (%esp); \
6424: fstps (%esp); \
flds (%esp); \
addl $4, %esp; \
cfi_adjust_cfa_offset (-4);
#define DBL_NARROW_EVAL_UFLOW_NONNEG \
subl $8, %esp; \
cfi_adjust_cfa_offset (8); \
fcoml MO(dbl_min); \
fnstsw; \
sahf; \
jnc 6453f; \
fld %st(0); \
fmul %st(0); \
fstpl (%esp); \
6453: fstpl (%esp); \
fldl (%esp); \
addl $8, %esp; \
cfi_adjust_cfa_offset (-8);
/* Likewise, but the non-NaN argument may be negative. */
#define FLT_NARROW_EVAL_UFLOW_NONNAN \
subl $4, %esp; \
cfi_adjust_cfa_offset (4); \
fld %st(0); \
fabs; \
fcomps MO(flt_min); \
fnstsw; \
sahf; \
jnc 6424f; \
fld %st(0); \
fmul %st(0); \
fstps (%esp); \
6424: fstps (%esp); \
flds (%esp); \
addl $4, %esp; \
cfi_adjust_cfa_offset (-4);
#define DBL_NARROW_EVAL_UFLOW_NONNAN \
subl $8, %esp; \
cfi_adjust_cfa_offset (8); \
fld %st(0); \
fabs; \
fcompl MO(dbl_min); \
fnstsw; \
sahf; \
jnc 6453f; \
fld %st(0); \
fmul %st(0); \
fstpl (%esp); \
6453: fstpl (%esp); \
fldl (%esp); \
addl $8, %esp; \
cfi_adjust_cfa_offset (-8);
/* Force an underflow exception if the given value is subnormal. The
relevant constant for the minimum of the type must have been
defined, the MO macro must have been defined for access to memory
operands, and, if PIC, the PIC register must have been loaded. */
#define FLT_CHECK_FORCE_UFLOW \
flds MO(flt_min); \
fld %st(1); \
fabs; \
fucompp; \
fnstsw; \
sahf; \
jnc 6424f; \
subl $4, %esp; \
cfi_adjust_cfa_offset (4); \
fld %st(0); \
fmul %st(0); \
fstps (%esp); \
addl $4, %esp; \
cfi_adjust_cfa_offset (-4); \
6424:
#define DBL_CHECK_FORCE_UFLOW \
fldl MO(dbl_min); \
fld %st(1); \
fabs; \
fucompp; \
fnstsw; \
sahf; \
jnc 6453f; \
subl $8, %esp; \
cfi_adjust_cfa_offset (8); \
fld %st(0); \
fmul %st(0); \
fstpl (%esp); \
addl $8, %esp; \
cfi_adjust_cfa_offset (-8); \
6453:
/* Likewise, but also remove excess range and precision if the value
is subnormal. */
#define FLT_CHECK_FORCE_UFLOW_NARROW \
flds MO(flt_min); \
fld %st(1); \
fabs; \
fucompp; \
fnstsw; \
sahf; \
jnc 6424f; \
subl $4, %esp; \
cfi_adjust_cfa_offset (4); \
fld %st(0); \
fmul %st(0); \
fstps (%esp); \
fstps (%esp); \
flds (%esp); \
addl $4, %esp; \
cfi_adjust_cfa_offset (-4); \
6424:
#define DBL_CHECK_FORCE_UFLOW_NARROW \
fldl MO(dbl_min); \
fld %st(1); \
fabs; \
fucompp; \
fnstsw; \
sahf; \
jnc 6453f; \
subl $8, %esp; \
cfi_adjust_cfa_offset (8); \
fld %st(0); \
fmul %st(0); \
fstpl (%esp); \
fstpl (%esp); \
fldl (%esp); \
addl $8, %esp; \
cfi_adjust_cfa_offset (-8); \
6453:
/* Likewise, but the argument is nonnegative or NaN. */
#define LDBL_CHECK_FORCE_UFLOW_NONNEG_NAN \
fldt MO(ldbl_min); \
fld %st(1); \
fucompp; \
fnstsw; \
sahf; \
jnc 6464f; \
fld %st(0); \
fmul %st(0); \
fstp %st(0); \
6464:
/* Likewise, but the argument is not a NaN. */
#define FLT_CHECK_FORCE_UFLOW_NONNAN \
fld %st(0); \
fabs; \
fcomps MO(flt_min); \
fnstsw; \
sahf; \
jnc 6424f; \
subl $4, %esp; \
cfi_adjust_cfa_offset (4); \
fld %st(0); \
fmul %st(0); \
fstps (%esp); \
addl $4, %esp; \
cfi_adjust_cfa_offset (-4); \
6424:
#define DBL_CHECK_FORCE_UFLOW_NONNAN \
fld %st(0); \
fabs; \
fcompl MO(dbl_min); \
fnstsw; \
sahf; \
jnc 6453f; \
subl $8, %esp; \
cfi_adjust_cfa_offset (8); \
fld %st(0); \
fmul %st(0); \
fstpl (%esp); \
addl $8, %esp; \
cfi_adjust_cfa_offset (-8); \
6453:
#define LDBL_CHECK_FORCE_UFLOW_NONNAN \
fldt MO(ldbl_min); \
fld %st(1); \
fabs; \
fcompp; \
fnstsw; \
sahf; \
jnc 6464f; \
fld %st(0); \
fmul %st(0); \
fstp %st(0); \
6464:
/* Likewise, but the argument is nonnegative and not a NaN. */
#define FLT_CHECK_FORCE_UFLOW_NONNEG \
fcoms MO(flt_min); \
fnstsw; \
sahf; \
jnc 6424f; \
subl $4, %esp; \
cfi_adjust_cfa_offset (4); \
fld %st(0); \
fmul %st(0); \
fstps (%esp); \
addl $4, %esp; \
cfi_adjust_cfa_offset (-4); \
6424:
#define DBL_CHECK_FORCE_UFLOW_NONNEG \
fcoml MO(dbl_min); \
fnstsw; \
sahf; \
jnc 6453f; \
subl $8, %esp; \
cfi_adjust_cfa_offset (8); \
fld %st(0); \
fmul %st(0); \
fstpl (%esp); \
addl $8, %esp; \
cfi_adjust_cfa_offset (-8); \
6453:
#define LDBL_CHECK_FORCE_UFLOW_NONNEG \
fldt MO(ldbl_min); \
fld %st(1); \
fcompp; \
fnstsw; \
sahf; \
jnc 6464f; \
fld %st(0); \
fmul %st(0); \
fstp %st(0); \
6464:
#endif /* i386-math-asm.h. */
|
