1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
/* Compute the hypothenuse of X and Y.
Copyright (C) 1998-2017 Free Software Foundation, Inc.
This file is part of the GNU C Library.
Contributed by Ulrich Drepper <drepper@cygnus.com>, 1998.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, see
<http://www.gnu.org/licenses/>. */
#include <sysdep.h>
#include <i386-math-asm.h>
.text
ENTRY(__ieee754_hypotf)
flds 4(%esp) // x
fxam
fnstsw
flds 8(%esp) // y : x
movb %ah, %ch
fxam
fnstsw
movb %ah, %al
orb %ch, %ah
sahf
jc 1f
fmul %st(0) // y * y : x
fxch // x : y * y
fmul %st(0) // x * x : y * y
faddp // x * x + y * y
fsqrt
FLT_NARROW_EVAL
2: ret
// We have to test whether any of the parameters is Inf.
// In this case the result is infinity.
1: andb $0x45, %al
cmpb $5, %al
je 3f // jump if y is Inf
andb $0x45, %ch
cmpb $5, %ch
jne 4f // jump if x is not Inf
fxch
3: fstp %st(1)
fabs
jmp 2b
4: testb $1, %al
jnz 5f // y is NaN
fxch
5: fstp %st(1)
jmp 2b
END(__ieee754_hypotf)
strong_alias (__ieee754_hypotf, __hypotf_finite)
|
