blob: 1812b34398fa4d48e51ef059c5348f455514407c (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
/*
* Written by Ulrich Drepper.
*/
#include <machine/asm.h>
#include <i386-math-asm.h>
DEFINE_FLT_MIN
#ifdef PIC
# define MO(op) op##@GOTOFF(%ecx)
#else
# define MO(op) op
#endif
.text
/* 10^x = 2^(x * log2(10)) */
ENTRY(__ieee754_exp10f)
#ifdef PIC
LOAD_PIC_REG (cx)
#endif
flds 4(%esp)
/* I added the following ugly construct because exp(+-Inf) resulted
in NaN. The ugliness results from the bright minds at Intel.
For the i686 the code can be written better.
-- drepper@cygnus.com. */
fxam /* Is NaN or +-Inf? */
fstsw %ax
movb $0x45, %dh
andb %ah, %dh
cmpb $0x05, %dh
je 1f /* Is +-Inf, jump. */
fldl2t
fmulp /* x * log2(10) */
fld %st
frndint /* int(x * log2(10)) */
fsubr %st,%st(1) /* fract(x * log2(10)) */
fxch
f2xm1 /* 2^(fract(x * log2(10))) - 1 */
fld1
faddp /* 2^(fract(x * log2(10))) */
fscale /* e^x */
fstp %st(1)
FLT_NARROW_EVAL_UFLOW_NONNEG_NAN
ret
1: testl $0x200, %eax /* Test sign. */
jz 2f /* If positive, jump. */
fstp %st
fldz /* Set result to 0. */
2: ret
END (__ieee754_exp10f)
strong_alias (__ieee754_exp10f, __exp10f_finite)
|
