1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
|
/* ix87 specific implementation of arctanh function.
Copyright (C) 1996, 1999, 2011-2012 Free Software Foundation, Inc.
This file is part of the GNU C Library.
Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, write to the Free
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
02111-1307 USA. */
#include <machine/asm.h>
.section .rodata
.align ALIGNARG(4)
/* Please note that we use double values for 0.5 and 1.0. These
numbers have exact representations and so we don't get accuracy
problems. The advantage is that the code is simpler. */
ASM_TYPE_DIRECTIVE(half,@object)
half: .double 0.5
ASM_SIZE_DIRECTIVE(half)
ASM_TYPE_DIRECTIVE(one,@object)
one: .double 1.0
ASM_SIZE_DIRECTIVE(one)
/* It is not important that this constant is precise. It is only
a value which is known to be on the safe side for using the
fyl2xp1 instruction. */
ASM_TYPE_DIRECTIVE(limit,@object)
limit: .double 0.29
ASM_SIZE_DIRECTIVE(limit)
.align ALIGNARG(4)
ASM_TYPE_DIRECTIVE(ln2_2,@object)
ln2_2: .tfloat 0.3465735902799726547086160
ASM_SIZE_DIRECTIVE(ln2_2)
#ifdef PIC
#define MO(op) op##@GOTOFF(%edx)
#else
#define MO(op) op
#endif
.text
ENTRY(__ieee754_atanhl)
movl 12(%esp), %ecx
movl %ecx, %eax
andl $0x7fff, %eax
cmpl $0x7fff, %eax
je 5f
7:
#ifdef PIC
LOAD_PIC_REG (dx)
#endif
andl $0x8000, %ecx // ECX == 0 iff X >= 0
fldt MO(ln2_2) // 0.5*ln2
xorl %ecx, 12(%esp)
fldt 4(%esp) // |x| : 0.5*ln2
fcoml MO(half) // |x| : 0.5*ln2
fld %st(0) // |x| : |x| : 0.5*ln2
fnstsw // |x| : |x| : 0.5*ln2
sahf
jae 2f
fadd %st, %st(1) // |x| : 2*|x| : 0.5*ln2
fld %st // |x| : |x| : 2*|x| : 0.5*ln2
fsubrl MO(one) // 1-|x| : |x| : 2*|x| : 0.5*ln2
fxch // |x| : 1-|x| : 2*|x| : 0.5*ln2
fmul %st(2) // 2*|x|^2 : 1-|x| : 2*|x| : 0.5*ln2
fdivp // (2*|x|^2)/(1-|x|) : 2*|x| : 0.5*ln2
faddp // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
fcoml MO(limit) // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
fnstsw // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
sahf
jae 4f
fyl2xp1 // 0.5*ln2*ld(1+2*|x|+(2*|x|^2)/(1-|x|))
jecxz 3f
fchs // 0.5*ln2*ld(1+2*x+(2*x^2)/(1-x))
3: ret
.align ALIGNARG(4)
4: faddl MO(one) // 1+2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
fyl2x // 0.5*ln2*ld(1+2*|x|+(2*|x|^2)/(1-|x|))
jecxz 3f
fchs // 0.5*ln2*ld(1+2*x+(2*x^2)/(1-x))
3: ret
.align ALIGNARG(4)
2: faddl MO(one) // 1+|x| : |x| : 0.5*ln2
fxch // |x| : 1+|x| : 0.5*ln2
fsubrl MO(one) // 1-|x| : 1+|x| : 0.5*ln2
fdivrp // (1+|x|)/(1-|x|) : 0.5*ln2
fyl2x // 0.5*ln2*ld((1+|x|)/(1-|x|))
jecxz 3f
fchs // 0.5*ln2*ld((1+x)/(1-x))
3: ret
// x == NaN or ±Inf
5: cmpl $0x80000000, 8(%esp)
ja 6f
cmpl $0, 4(%esp)
je 7b
6: fldt 4(%esp)
ret
END(__ieee754_atanhl)
strong_alias (__ieee754_atanhl, __atanhl_finite)
|
