1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
|
/* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
This file is part of the GNU C Library.
Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, write to the Free
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
02111-1307 USA. */
#include <sysdep.h>
#include <lowlevelrwlock.h>
#define SYS_gettimeofday __NR_gettimeofday
#define SYS_futex 240
#define FUTEX_WAIT 0
#define FUTEX_WAKE 1
#define EAGAIN 11
#define EINVAL 22
#define EDEADLK 35
#define ETIMEDOUT 110
#ifndef UP
# define LOCK lock
#else
# define LOCK
#endif
.text
.globl pthread_rwlock_timedwrlock
.type pthread_rwlock_timedwrlock,@function
.align 16
pthread_rwlock_timedwrlock:
pushl %esi
pushl %edi
pushl %ebx
pushl %ebp
subl $8, %esp
movl 28(%esp), %ebp
movl 32(%esp), %edi
/* Get the lock. */
movl $1, %eax
LOCK
#if MUTEX == 0
xaddl %eax, (%ebp)
#else
xaddl %eax, MUTEX(%ebp)
#endif
testl %eax, %eax
jne 1f
2: movl WRITER(%ebp), %eax
testl %eax, %eax
jne 14f
cmp $0, NR_READERS(%ebp)
je 5f
/* Check the value of the timeout parameter. */
3: cmpl $1000000000, 4(%edi)
jae 19f
incl WRITERS_QUEUED(%ebp)
je 4f
LOCK
#if MUTEX == 0
decl (%ebp)
#else
decl MUTEX(%ebp)
#endif
jne 10f
/* Get current time. */
11: movl %esp, %ebx
xorl %ecx, %ecx
movl $SYS_gettimeofday, %eax
ENTER_KERNEL
/* Compute relative timeout. */
movl 4(%esp), %eax
movl $1000, %edx
mul %edx /* Milli seconds to nano seconds. */
movl (%edi), %ecx
movl 4(%edi), %edx
subl (%esp), %ecx
subl %eax, %edx
jns 15f
addl $1000000000, %edx
decl %ecx
15: testl %ecx, %ecx
js 16f /* Time is already up. */
/* Futex call. */
movl %ecx, (%esp) /* Store relative timeout. */
movl %edx, 4(%esp)
xorl %ecx, %ecx /* movl $FUTEX_WAIT, %ecx */
movl %esp, %esi
movl %ecx, %edx
leal WRITERS_WAKEUP(%ebp), %ebx
movl $SYS_futex, %eax
ENTER_KERNEL
movl %eax, %edx
17:
/* Reget the lock. */
movl $1, %eax
LOCK
#if MUTEX == 0
xaddl %eax, (%ebp)
#else
xaddl %eax, MUTEX(%ebp)
#endif
testl %eax, %eax
jne 12f
13: cmpl $-ETIMEDOUT, %ecx
je 18f
decl WRITERS_QUEUED(%ebp)
movl $0, WRITERS_WAKEUP(%ebp)
jmp 2b
5: xorl %ecx, %ecx
movl %gs:8, %eax
movl %eax, WRITER(%ebp)
9: LOCK
#if MUTEX == 0
decl (%ebp)
#else
decl MUTEX(%ebp)
#endif
jne 6f
7: movl %ecx, %eax
addl $8, %esp
popl %ebp
popl %ebx
popl %edi
popl %esi
ret
1: movl %ebp, %ecx
call __lll_mutex_lock_wait
jmp 2b
14: cmpl %gs:8, %eax
jne 3b
20: movl $EDEADLK, %ecx
jmp 9b
6: movl %ebp, %eax
call __lll_mutex_unlock_wake
jmp 7b
/* Overflow. */
4: decl WRITERS_QUEUED(%ebp)
movl $EAGAIN, %ecx
jmp 9b
10: movl %ebp, %eax
call __lll_mutex_unlock_wake
jmp 11b
12: movl %ebx, %ecx
call __lll_mutex_lock_wait
jmp 13b
16: movl $-ETIMEDOUT, %ecx
jmp 17b
18: movl $ETIMEDOUT, %ecx
jmp 9b
19: movl $EINVAL, %ecx
jmp 9b
.size pthread_rwlock_timedwrlock,.-pthread_rwlock_timedwrlock
|
