From 76e95c889908f409c2913e6abd23ba5fedb1459f Mon Sep 17 00:00:00 2001
From: Ulrich Drepper <drepper@redhat.com>
Date: Sun, 16 Oct 2005 15:49:27 +0000
Subject: * sysdeps/unix/sysv/linux/sh/makecontext.S: New file.

	* sysdeps/unix/sysv/linux/sh/sh3/getcontext.S: New file.
	* sysdeps/unix/sysv/linux/sh/sh4/getcontext.S: New file.
	* sysdeps/unix/sysv/linux/sh/sh3/setcontext.S: New file.
	* sysdeps/unix/sysv/linux/sh/sh4/setcontext.S: New file.
	* sysdeps/unix/sysv/linux/sh/sh3/swapcontext.S: New file.
	* sysdeps/unix/sysv/linux/sh/sh4/swapcontext.S: New file.
	* sysdeps/unix/sysv/linux/sh/sh3/ucontext_i.h: New file.
	* sysdeps/unix/sysv/linux/sh/sh4/ucontext_i.h: New file.
	* sysdeps/unix/sysv/linux/sh/sys/ucontext.h: Removed.
	* sysdeps/unix/sysv/linux/sh/sh3/sys/ucontext.h: New file.
	* sysdeps/unix/sysv/linux/sh/sh4/sys/ucontext.h: New file.
---
 sysdeps/unix/sysv/linux/sh/sh3/getcontext.S | 90 +++++++++++++++++++++++++++++
 1 file changed, 90 insertions(+)
 create mode 100644 sysdeps/unix/sysv/linux/sh/sh3/getcontext.S

(limited to 'sysdeps/unix/sysv/linux/sh/sh3/getcontext.S')

diff --git a/sysdeps/unix/sysv/linux/sh/sh3/getcontext.S b/sysdeps/unix/sysv/linux/sh/sh3/getcontext.S
new file mode 100644
index 0000000000..3ea47d4a5c
--- /dev/null
+++ b/sysdeps/unix/sysv/linux/sh/sh3/getcontext.S
@@ -0,0 +1,90 @@
+/* Save current context.
+   Copyright (C) 2005 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+
+#include "ucontext_i.h"
+
+/*  int __getcontext (ucontext_t *uc);  */
+
+	.text
+	.align  5
+	cfi_startproc
+ENTRY(__getcontext)
+
+	/* Return value of getcontext.  R0 is the only register whose
+	   value is not preserved.  */
+	mov	#0, r0
+	mov.l	r0, @(oR0,r4)
+	mov.l	r1, @(oR1,r4)
+	mov.l	r2, @(oR2,r4)
+	mov.l	r3, @(oR3,r4)
+	mov.l	r4, @(oR4,r4)
+	mov.l	r5, @(oR5,r4)
+	mov.l	r6, @(oR6,r4)
+	mov.l	r7, @(oR7,r4)
+	mov	r4, r0
+	add	#(oMACL+4), r0
+	sts.l	macl, @-r0
+	sts.l	mach, @-r0
+	stc.l	gbr, @-r0
+
+	/* Save T flag to SR.  */
+	movt	r1
+	mov.l	r1, @-r0
+	sts.l	pr, @-r0
+
+	/* The return address of getcontext is the restart pc.  */
+	sts.l	pr, @-r0
+
+	mov.l	r15, @-r0
+	mov.l	r14, @-r0
+	mov.l	r13, @-r0
+	mov.l	r12, @-r0
+	mov.l	r11, @-r0
+	mov.l	r10, @-r0
+	mov.l	r9, @-r0
+	mov.l	r8, @-r0
+
+	/* sigprocmask (SIG_BLOCK, NULL, &uc->uc_sigmask).  */
+	mov	r4, r6
+	add	#oSIGMASK, r6
+	mov	#SIG_BLOCK, r4
+	mov	#0, r5
+	mov	#+SYS_ify(sigprocmask), r3
+	trapa	#0x13
+	mov     r0, r1
+	mov	#-12, r2
+	shad	r2, r1
+	not	r1, r1			// r1=0 means r0 = -1 to -4095
+	tst	r1, r1			// i.e. error in linux
+	bf	.Lgetcontext_end
+.Lsyscall_error:	
+	SYSCALL_ERROR_HANDLER
+.Lgetcontext_end:
+	/* All done, return 0 for success.  */
+	mov	#0, r0
+.Lpseudo_end:
+	rts
+	 nop
+
+	cfi_endproc
+PSEUDO_END(__getcontext)
+
+weak_alias (__getcontext, getcontext)
-- 
cgit 1.4.1