Update.

2000-11-06  Hideaki YOSHIFUJI  <yoshfuji@linux-ipv6.org>

	* sysdeps/posix/getaddrinfo.c: Clean-up: define family to hold
	target family.

2000-11-06  Hideaki YOSHIFUJI  <yoshfuji@linux-ipv6.org>

	* sysdeps/posix/getaddrinfo.c: Loosen protocol check to ease raw
	socket creation.

2000-11-06  Hideaki YOSHIFUJI  <yoshfuji@linux-ipv6.org>

	* sysdeps/posix/getaddrinfo.c: Ensure to fill ai_socktype and
	ai_protocol by internal table if service was not given.

2000-11-06  Hideaki YOSHIFUJI  <yoshfuji@linux-ipv6.org>

	* sysdeps/posix/getaddrinfo.c: Don't raise an error even if
	numerical port was specified with protocol without socktype.

2000-11-06  Hideaki YOSHIFUJI  <yoshfuji@linux-ipv6.org>

	* sysdeps/posix/getaddrinfo.c: Ensure to check if protocol is ok.

2000-11-06  Hideaki YOSHIFUJI  <yoshfuji@linux-ipv6.org>

	* inet/getnameinfo.c: getnameinfo() NI_xxx flag validation.

2000-11-06  Hideaki YOSHIFUJI  <yoshfuji@linux-ipv6.org>

	* sysdeps/posix/getaddrinfo.c: Ensure not to fill garbage value in
	sin6_scope_id field.

2000-11-06  Hideaki YOSHIFUJI  <yoshfuji@linux-ipv6.org>

	* inet/getnameinfo.c: Repair getnameinfo() sin6_socpe_id support.

2000-11-06  Hideaki YOSHIFUJI  <yoshfuji@linux-ipv6.org>

	* inet/getnameinfo.c: Repair NI_NOFQDN flag support.

2000-11-06  Hideaki YOSHIFUJI  <yoshfuji@linux-ipv6.org>

	* inet/getnameinfo.c: Wake-up sin6_scope_id support in
	getnameinfo(): check for whether sin6_socpe_id exist was wrong.

2000-11-09  Martin Schwidefsky  <mschwide@nc.boeblingen.de.ibm.com>

	* sysdeps/unix/sysv/linux/s390/mmap.S: Use mmap2 if it is present.
	* sysdeps/unix/sysv/linux/s390/mmap64.S: New file.

2 files changed, 132 insertions, 19 deletions

diff --git a/sysdeps/unix/sysv/linux/s390/mmap.S b/sysdeps/unix/sysv/linux/s390/mmap.S
index 0ba58ccf82..f9650e9f03 100644
--- a/sysdeps/unix/sysv/linux/s390/mmap.S
+++ b/sysdeps/unix/sysv/linux/s390/mmap.S
@@ -19,33 +19,45 @@
 
 #include <sysdep.h>
 
-	.text
+#define EINVAL  22
 
+	.text
 ENTRY(__mmap)
 	/* Save registers and setup stack frame.  */
 	stm     %r6,%r15,24(%r15)
 	lr      %r1,%r15
-	l       %r0,4(0,%r15)           /* load eos */
 	ahi     %r15,-120               /* buy stack space */
-	st      %r1,0(0,%r15)           /* store back chain */
-	st      %r0,4(0,%r15)           /* store eos */
+	st      %r1,0(%r15)             /* store back chain */
 
-	/* Store parameters on stack, because old_mmap
-	 * takes only one parameter: a pointer to the parameter area
+	/* Store parameters on stack, because old_mmap/mmap2
+	 * take only one parameter: a pointer to the parameter area
 	 */
-	mvc     0x74(4,%r15),216(%r15)  /* move 'offset'  */
-	st      %r6,0x70(0,%r15)        /* store 'fd'     */
-	st      %r5,0x6C(0,%r15)        /* store 'flags'  */
-	st      %r4,0x68(0,%r15)        /* store 'prot'   */
-	st      %r3,0x64(0,%r15)        /* store 'length' */
-	st      %r2,0x60(0,%r15)        /* store 'start'  */
-
-	la      %r2,0x60(0,%r15)        /* load address of parameter list */
-	/* Do the system call trap.  */
-	svc     SYS_ify(mmap)
-
-	l       %r15,0(0,%r15)          /* load back chain */
-	lm      %r6,%r15,24(%r15)       /* load registers */
+	st      %r6,0x70(%r15)          /* Store 'fd'.      */
+	st      %r5,0x6C(%r15)          /* Store 'flags'.   */
+	st      %r4,0x68(%r15)          /* Store 'prot'.    */
+	st      %r3,0x64(%r15)          /* Store 'length'.  */
+	st      %r2,0x60(%r15)          /* Store 'start'.   */
+	l       %r1,216(%r15)           /* Load offset.     */
+
+#ifdef __ASSUME_MMAP2_SYSCALL
+	/* I don't think it is worthwhile trying to use mmap2 whenever 
+	 * it is available.  Only use it when we are sure the syscall
+	 * exists.  */
+	tml     %r1,0x0fff              /* Offset page aligned ?  */
+	lhi     %r2,-EINVAL
+	jnz     1f                      /* No -> EINVAL.  */
+	srl     %r1,12                  /* mmap2 takes the offset in pages.  */
+	st      %r1,0x74(%r15)          /* Store page offset.  */
+	la      %r2,0x60(%r15)          /* Load address of parameter list.  */
+	svc     SYS_ify(mmap2)          /* Do the system call trap.  */
+#else	
+	st      %r1,0x74(%r15)          /* Store offset unmodified.  */
+	la      %r2,0x60(%r15)          /* Load address of parameter list.  */
+	svc     SYS_ify(mmap)           /* Do the system call trap.  */
+#endif
+
+1:	l       %r15,0(%r15)            /* Load back chain.  */
+	lm      %r6,%r15,24(%r15)       /* Load registers.  */
 
 	/* check gpr 2 for error */
 	lhi     %r0,-4096
diff --git a/sysdeps/unix/sysv/linux/s390/mmap64.S b/sysdeps/unix/sysv/linux/s390/mmap64.S
new file mode 100644
index 0000000000..96b2af5741
--- /dev/null
+++ b/sysdeps/unix/sysv/linux/s390/mmap64.S
@@ -0,0 +1,101 @@
+/* Copyright (C) 2000 Free Software Foundation, Inc.
+   Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Library General Public License as
+   published by the Free Software Foundation; either version 2 of the
+   License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Library General Public License for more details.
+
+   You should have received a copy of the GNU Library General Public
+   License along with the GNU C Library; see the file COPYING.LIB.  If not,
+   write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+   Boston, MA 02111-1307, USA.  */
+
+#include <sysdep.h>
+
+#define EINVAL  22
+#define ENOSYS  38
+
+	.text
+ENTRY(__mmap64)
+	/* Save registers and setup stack frame.  */
+	stm     %r6,%r15,24(%r15)
+	lr      %r1,%r15
+	ahi     %r15,-120               /* Buy stack space.   */
+	st      %r1,0(%r15)             /* Store back chain.  */
+
+	/* Store parameters on stack, because mmap2 and old_mmap
+	 * take only one parameter: a pointer to the parameter area.  */
+	st      %r6,0x70(%r15)          /* Store 'fd'.      */
+	st      %r5,0x6C(%r15)          /* Store 'flags'.   */
+	st      %r4,0x68(%r15)          /* Store 'prot'.    */
+	st      %r3,0x64(%r15)          /* Store 'length'.  */
+	st      %r2,0x60(%r15)          /* Store 'start'.   */
+
+#ifdef __NR_mmap2
+	lm      %r0,%r1,216(%r15)       /* Load 64 bit offset.  */
+	tml     %r1,0x0fff              /* Offset page aligned ?  */
+	jnz     2f                      /* No -> EINVAL.  */
+	srdl    %r0,12                  /* mmap2 takes the offset in pages.  */
+	ltr     %r0,%r0                 /* Offset > 2^44 ?  */
+	jnz     2f
+	st      %r1,0x74(%r15)          /* Store page offset.  */
+
+	la      %r2,0x60(%r15)          /* Load address of parameter list.  */
+	svc     SYS_ify(mmap2)          /* Do the system call trap.  */
+
+#ifndef __ASSUME_MMAP2_SYSCALL
+	chi     %r0,-ENOSYS
+	je	1f
+#endif
+
+	l       %r15,0(%r15)            /* Load back chain.  */
+	lm      %r6,%r15,24(%r15)       /* Load registers.  */
+
+	/* Check gpr 2 for error.  */
+	lhi     %r0,-4096
+	clr     %r2,%r0
+	jnl     SYSCALL_ERROR_LABEL
+
+	/* Successful; return the syscall's value.  */
+	br      %r14
+
+#endif
+
+#if !defined __ASSUME_MMAP2_SYSCALL || !defined __NR_mmap2
+1:	lm      %r0,%r1,216(%r15)       /* Load 64 bit offset.  */
+	st      %r1,0x74(%r15)          /* Store lower word of offset.  */
+	ltr     %r0,%r0                 /* Offset > 2^32 ?  */
+	jnz     2f
+	alr     %r1,%r3                 /* Add length to offset.  */
+	brc     3,2f                    /* Carry -> EINVAL.  */
+
+	la      %r2,0x60(%r15)          /* Load address of parameter list.  */
+	svc     SYS_ify(mmap2)          /* Do the system call trap.  */
+
+	l       %r15,0(%r15)            /* Load back chain.  */
+	lm      %r6,%r15,24(%r15)       /* Load registers.  */
+
+	/* Check gpr 2 for error.  */
+	lhi     %r0,-4096
+	clr     %r2,%r0
+	jnl     SYSCALL_ERROR_LABEL
+
+	/* Successful; return the syscall's value.  */
+	br      %r14
+#endif
+
+2:	lhi     %r2,-EINVAL
+	l       %r15,0(%r15)            /* Load back chain.  */
+	lm      %r6,%r15,24(%r15)       /* Load registers.  */
+	j       SYSCALL_ERROR_LABEL
+	
+PSEUDO_END (__mmap64)
+
+weak_alias (__mmap64, mmap64)