update from main archive 970101 cvs/libc-970102

Wed Jan  1 15:15:00 1997  Ulrich Drepper  <drepper@cygnus.com>

	* libio/Makefile (routines): Add fcloseall.
	* libio/fcloseall.c: New file.
	* libio/stdio.h [__USE_GNU]: Add prototype for fcloseall.
	* libio/iofclose.c: Don't close all streams when argument is NULL.

	* stdio/Makefile (routines): Add fcloseall.
	* stdio/fcloseall.c: New file.
	* stdio/stdio.h [__USE_GNU]: Add prototype for fcloseall.
	* stdio/fclose.c: Don't close all streams when argument is NULL.

	* manual/stdio.texi: Document fcloseall.

	* sysdeps/generic/abort.c: Call __fcloseall instead of fclose with
	NULL argument.

	* socket/sys/un.h (SUN_LEN): Add cast.

	* sunrpc/auth_unix.c (authunix_create): Change parameter types
	of uid, gid, and aup_gids to uid_t and gid_t respectively.
	(authunix_create_default): Likewise.
	(authunix_refresh): Correct cast for aup_gids assignment.
	* sunrpc/rpc/auth.h (authunix_create): Correct types in declaration.
	* sunrpc/rpc/auth_unix.h (struct authunix_parms): Correct field
	types to uid_t and gid_t respectively.
	(struct short_hand_verf): Likewise.
	Reported by Andreas Schwab.

	* sysdeps/ieee754/Makefile: New file.  Make sure ieee754.h gets
	installed.
	* sysdeps/ieee754/ieee754.h: Protect against multiple inclusion and
	use in C++ programs.

	* sysdeps/libm-i387/e_pow.S: New file.  Optimized ix87 assembler
	version of pow() function.
	* sysdeps/libm-i387/e_powf.S: New file.  Float version.
	* sysdeps/libm-i387/e_powl.S: New file.  Long double version.

	* sysdeps/libm-i387/s_expm1.S: New file.  Optimized ix87 assembler
	version of expm1() function.
	* sysdeps/libm-i387/s_expm1f.S: New file.  Float version.
	* sysdeps/libm-i387/s_expm1l.S: New file.  Long double version.

	* sysdeps/libm-i387/e_exp.S: Optimize handling of +-Inf.
	Better handling of computation stack from current NetBSD sources.
	* sysdeps/libm-i387/e_expf.S: Likewise.
	* sysdeps/libm-i387/e_expl.S: Likewise.

	* sysdeps/libm-i387/e_log.S: Use fstp instead of fincstp.
	* sysdeps/libm-i387/e_logf.S: Likewise.
	* sysdeps/libm-i387/e_logl.S: Likewise.
	* sysdeps/libm-i387/e_log10.S: Likewise.
	* sysdeps/libm-i387/e_log10f.S: Likewise.
	* sysdeps/libm-i387/e_log10l.S: Likewise.
	* sysdeps/libm-i387/s_asinh.S: Likewise.
	* sysdeps/libm-i387/s_asinhf.S: Likewise.
	* sysdeps/libm-i387/s_asinhl.S: Likewise.
	* sysdeps/libm-i387/s_significandl.S: Likewise.

	* sysdeps/libm-i387/s_ceil.S: Don't create stack frame.  Modify
	stack pointer directly.  Use 32 bit instead of 16 bit operations.
	* sysdeps/libm-i387/s_ceilf.S: Likewise.
	* sysdeps/libm-i387/s_ceill.S: Likewise.
	* sysdeps/libm-i387/s_floor.S: Likewise.
	* sysdeps/libm-i387/s_floorf.S: Likewise.
	* sysdeps/libm-i387/s_floorl.S: Likewise.

	* sysdeps/libm-ieee754/e_coshf.c (huge): Don't declare volatile.
	* sysdeps/libm-ieee754/e_expf.c: Likewise.
	* sysdeps/libm-ieee754/e_powf.c: Likewise.
	From current NetBSD sources.

	* sysdeps/libm-ieee754/e_hypot.c (__ieee754_hypot): Don't initialize
	`a' and `b' in definition.
	* sysdeps/libm-ieee754/e_hypotf.c: Likewise.

	* sysdeps/libm-ieee754/e_hypotl.c: New file.  Long double
	implementation.
	* sysdeps/libm-ieee754/e_sinhl.c: New file.  Long double
	implementation.
	* sysdeps/stub/e_hypotl.c: Removed.  We have a real version now.
	* sysdeps/stub/e_sinhl.c: Removed.

	* sysdeps/posix/sigpause.c (__sigpause): Use sigdelset instead of
	sigaddset.  Reported by Andreas Schwab.
	(__default_sigpause): New function.  Call __sigpause as BSD version.
	Make this the default function by providing alias sigpause.
	* sysdeps/stub/sigpause.c (__default_sigpause): New funciton.
	Simply fail.  Provide alias sigpause.

Wed Jan  1 12:34:54 1997  Ulrich Drepper  <drepper@cygnus.com>

	* po/es.po: Update for glibc-1.98.
	* po/fr.po: Likewise.
	* po/sv.po: New file.  Swedish translation.

Wed Jan  1 12:18:07 1997   MacGyver  <macgyver@tos.net>

	* values.h: Fix typos: use SHRT_MAX but SHORT_MAX and SHRT_MIN but
	SHORT_MIN.

Tue Dec 24 23:10:21 1996  Andreas Schwab  <schwab@issan.informatik.uni-dortmund.de>

	* Makefile: Replace `stubs.h' by `gnu/stubs.h'.
	* features.h: Include <gnu/stubs.h> instead of <stubs.h>.

Tue Dec 24 22:16:55 1996  Andreas Schwab  <schwab@issan.informatik.uni-dortmund.de>

	* Makefile (subdirs): Move `elf' last so that librtld.so isn't
	relinked in the `make others' pass if an add-on adds something to
	libc.

Mon Dec 23 21:23:16 1996  Andreas Schwab  <schwab@issan.informatik.uni-dortmund.de>

	* sysdeps/m68k/abort-instr.h: New File.

Mon Dec 23 21:16:38 1996  Andreas Schwab  <schwab@issan.informatik.uni-dortmund.de>

	* sysdeps/m68k/Makefile ($(subdir)=elf): Define CFLAGS-rtld.c
	to prevent warning.

Mon Dec 23 21:14:22 1996  Andreas Schwab  <schwab@issan.informatik.uni-dortmund.de>

	* resolv/Makefile (subdirs-dirs): Define.

Mon Dec 23 20:56:49 1996  Andreas Schwab  <schwab@issan.informatik.uni-dortmund.de>

	* sysdeps/gnu/utmpbits.h (struct utmp): Fix padding.

Mon Dec 30 11:05:11 1996  Ulrich Drepper  <drepper@cygnus.com>

	Update from ADO tzcode1996o.
	* time/difftime.c: De-ANSI-declfy.  Simplify computation of hibit
	according to ADO version.
	* time/zic.c: Correct typo is message.

	Update from ADO tzdata1996n.
	* time/asia: Updated.
	* time/australasia: Likewise.
	* time/europe: Likewise.
	* time/northamerica: Likewise.
	* time/southamerica: Likewise.

1 files changed, 120 insertions, 0 deletions

diff --git a/sysdeps/libm-i387/e_pow.S b/sysdeps/libm-i387/e_pow.S
new file mode 100644
index 0000000000..f6c7562d9c
--- /dev/null
+++ b/sysdeps/libm-i387/e_pow.S
@@ -0,0 +1,120 @@
+/* ix87 specific implementation of pow function.
+   Copyright (C) 1996 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+   Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Library General Public License as
+   published by the Free Software Foundation; either version 2 of the
+   License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Library General Public License for more details.
+
+   You should have received a copy of the GNU Library General Public
+   License along with the GNU C Library; see the file COPYING.LIB.  If not,
+   write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+   Boston, MA 02111-1307, USA.  */
+
+#include <machine/asm.h>
+
+#ifdef __ELF__
+	.section .rodata
+#else
+	.text
+#endif
+
+	.align ALIGNARG(4)
+	ASM_TYPE_DIRECTIVE(one,@object)
+one:	.double 1.0
+	ASM_SIZE_DIRECTIVE(one)
+	ASM_TYPE_DIRECTIVE(limit,@object)
+limit:	.double 0.29
+	ASM_SIZE_DIRECTIVE(limit)
+
+#ifdef PIC
+#define MO(op) op##@GOTOFF(%ecx)
+#else
+#define MO(op) op
+#endif
+
+	.text
+ENTRY(__ieee754_pow)
+	fldl	4(%esp)		// x
+	fldl	12(%esp)	// y : x
+
+#ifdef	PIC
+	call	1f
+1:	popl	%ecx
+	addl	$_GLOBAL_OFFSET_TABLE_+[.-1b], %ecx
+#endif
+	subl	$8,%esp
+
+	/* First see whether `y' is a natural number.  In this case we
+	   can use a more precise algorithm.  */
+	fld	%st		// y : y : x
+	fistpll	(%esp)		// y : x
+	fildll	(%esp)		// int(y) : y : x
+	fucomp	%st(1)		// y : x
+	fnstsw
+	sahf
+	jne	2f
+
+	/* OK, we have an integer value for y.  */
+	ftst			// y : x
+	fstp	%st(0)		// x
+	fnstsw
+	sahf
+	popl	%eax
+	popl	%edx
+	jnc	4f		// y >= 0, jump
+	fdivrl	MO(one)		// 1/x		(now referred to as x)
+	negl	%eax
+	adcl	$0, %edx
+	negl	%edx
+4:	fldl	MO(one)		// 1 : x
+	fxch
+
+6:	shrdl	$1, %edx, %eax
+	jnc	5f
+	fxch
+	fmul	%st(1)		// x : ST*x
+	fxch
+5:	fmul	%st(0), %st	// x*x : ST*x
+	movl	%eax, %ecx
+	orl	%edx, %ecx
+	jnz	6b
+	fstp	%st(0)		// ST*x
+	ret
+
+	.align ALIGNARG(4)
+2:	/* y is a real number.  */
+	fxch			// x : y
+	fldl	MO(one)		// 1.0 : x : y
+	fld	%st(1)		// x : 1.0 : x : y
+	fsub	%st(1)		// x-1 : 1.0 : x : y
+	fabs			// |x-1| : 1.0 : x : y
+	fcompl	MO(limit)	// 1.0 : x : y
+	fnstsw
+	fxch			// x : 1.0 : y
+	sahf
+	ja	7f
+	fsub	%st(1)		// x-1 : 1.0 : y
+	fyl2xp1			// log2(x) : y
+	jmp	8f
+
+7:	fyl2x			// log2(x) : y
+8:	fmul	%st(1)		// y*log2(x) : y
+	fst	%st(1)		// y*log2(x) : y*log2(x)
+	frndint			// int(y*log2(x)) : y*log2(x)
+	fsubr	%st, %st(1)	// int(y*log2(x)) : fract(y*log2(x))
+	fxch			// fract(y*log2(x)) : int(y*log2(x))
+	f2xm1			// 2^fract(y*log2(x))-1 : int(y*log2(x))
+	faddl	MO(one)		// 2^fract(y*log2(x)) : int(y*log2(x))
+	fscale			// 2^fract(y*log2(x))*2^int(y*log2(x)) : int(y*log2(x))
+	addl	$8, %esp
+	fstp	%st(1)		// 2^fract(y*log2(x))*2^int(y*log2(x))
+	ret
+END(__ieee754_pow)