Update.

2001-12-12  NIIBE Yutaka  <gniibe@m17n.org>

	* sysdeps/sh/Makefile: New file.
	* sysdeps/sh/_mcount.S: New file.
	* sysdeps/sh/sysdep.h (CALL_MCOUNT): Implemented.
	* sysdeps/sh/machine-gmon.h: Remove "NOTYET" comment, as we are ready.

6 files changed, 91 insertions, 3 deletions

diff --git a/ChangeLog b/ChangeLog
index b0f752913e..687e7f251f 100644
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,3 +1,10 @@
+2001-12-12  NIIBE Yutaka  <gniibe@m17n.org>
+
+	* sysdeps/sh/Makefile: New file.
+	* sysdeps/sh/_mcount.S: New file.
+	* sysdeps/sh/sysdep.h (CALL_MCOUNT): Implemented.
+	* sysdeps/sh/machine-gmon.h: Remove "NOTYET" comment, as we are ready.
+
 2001-12-11  Ulrich Drepper  <drepper@redhat.com>
 
 	* resolv/nss_dns/dns-host.c (getanswer_r): Remove MAX_NR_ADDRS
diff --git a/linuxthreads/ChangeLog b/linuxthreads/ChangeLog
index 438fd1a193..82472b5e03 100644
--- a/linuxthreads/ChangeLog
+++ b/linuxthreads/ChangeLog
@@ -1,3 +1,8 @@
+2001-12-12  NIIBE Yutaka  <gniibe@.m17n.org>
+
+	* sysdeps/sh/pt-machine.h (INIT_THREAD_SELF): Added __volatile__
+	qualifier to be safe.
+
 2001-11-30  Andreas Schwab  <schwab@suse.de>
 
 	* pthread.c (pthread_handle_sigcancel) [THREAD_SELF]: Double check
diff --git a/sysdeps/sh/Makefile b/sysdeps/sh/Makefile
new file mode 100644
index 0000000000..cf18dedc45
--- /dev/null
+++ b/sysdeps/sh/Makefile
@@ -0,0 +1,3 @@
+ifeq ($(subdir),gmon)
+sysdep_routines += _mcount
+endif
diff --git a/sysdeps/sh/_mcount.S b/sysdeps/sh/_mcount.S
new file mode 100644
index 0000000000..1e7a1d95c9
--- /dev/null
+++ b/sysdeps/sh/_mcount.S
@@ -0,0 +1,67 @@
+/* Machine-specific calling sequence for `mcount' profiling function.  SuperH
+   Copyright (C) 2001 Free Software Foundation, Inc.
+   Contributed by NIIBE Yutaka <gniibe@m17n.org>
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+
+	ASM_GLOBAL_DIRECTIVE C_SYMBOL_NAME(_mcount)
+	ASM_TYPE_DIRECTIVE (C_SYMBOL_NAME(_mcount),function)
+	.align	5
+C_LABEL(_mcount)
+	/* Save registers.  */
+	mov.l	r4,@-r15
+	mov.l	r5,@-r15
+	mov.l	r6,@-r15
+	mov.l	r7,@-r15
+	sts.l	pr,@-r15
+
+	mov.l	@(20,r15),r4
+	sts	pr,r5
+
+#ifdef SHARED
+	mov.l	0f,r1
+	mova	0f,r0
+	add	r1,r0
+	mov.l	1f,r1
+	mov.l	@(r0,r1),r1
+#else
+	mov.l	1f,r1
+#endif
+	jsr	@r1
+	 nop
+
+	/* Pop the saved registers.  */
+	lds.l	@r15+,pr
+	mov.l	@r15+,r7
+	mov.l	@r15+,r6
+	mov.l	@r15+,r5
+	rts
+	 mov.l	@r15+,r4
+
+	.align 2
+#ifdef SHARED
+0:	.long	_GLOBAL_OFFSET_TABLE_
+1:	.long	C_SYMBOL_NAME(__mcount_internal)@GOT
+#else
+1:	.long	C_SYMBOL_NAME(__mcount_internal)
+#endif
+ASM_SIZE_DIRECTIVE(C_SYMBOL_NAME(_mcount))
+
+#undef mcount
+weak_alias (_mcount, mcount)
diff --git a/sysdeps/sh/machine-gmon.h b/sysdeps/sh/machine-gmon.h
index 5ba944bbfd..46c7b191ad 100644
--- a/sysdeps/sh/machine-gmon.h
+++ b/sysdeps/sh/machine-gmon.h
@@ -17,8 +17,6 @@
    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
    02111-1307 USA.  */
 
-/* NOTYET  */
-
 /* We must not pollute the global namespace.  */
 #define mcount_internal __mcount_internal
 
diff --git a/sysdeps/sh/sysdep.h b/sysdeps/sh/sysdep.h
index 2e1e380908..202c701a10 100644
--- a/sysdeps/sh/sysdep.h
+++ b/sysdeps/sh/sysdep.h
@@ -60,7 +60,15 @@
 
 /* If compiled for profiling, call `mcount' at the start of each function.  */
 #ifdef	PROF
-#define CALL_MCOUNT	/* NOTYET */
+#define CALL_MCOUNT					\
+	mov.l	1f,r1;					\
+	sts.l	pr,@-r15;				\
+	mova	2f,r0;					\
+	jmp	@r1;					\
+	 lds	r0,pr;					\
+	.align	2;					\
+1:	.long	mcount;					\
+2:	lds.l	@r15+,pr
 #else
 #define CALL_MCOUNT		/* Do nothing.  */
 #endif